From 4e71dc1e3ae33df4fb96a4f1fca04cc12325320d Mon Sep 17 00:00:00 2001
From: Jeff Johnston <jjohnstn@redhat.com>
Date: Wed, 19 Apr 2006 19:44:05 +0000
Subject: 2006-04-19  Jeff Johnston  <jjohnstn@redhat.com>

        * configure.in: Modified to support autoconf 2.59.
        * */configure.in: Ditto.
        * configure: Regenerated.
        * */configure: Ditto.
        * wince/aclocal.m4: Ditto.
        * acinclude.m4: New file.
        * aclocal.m4: Ditto.
        * arm/aclocal.m4: Ditto.
        * cris/aclocal.m4: Ditto.
        * crx/aclocal.m4: Ditto.
        * d30v/aclocal.m4: Ditto.
        * fr30/aclocal.m4: Ditto.
        * frv/aclocal.m4: Ditto.
        * hp74x/aclocal.m4: Ditto.
        * i386/aclocal.m4: Ditto.
        * i960/aclocal.m4: Ditto.
        * iq2000/aclocal.m4: Ditto.
        * libnosys/aclocal.m4: Ditto.
        * m32c/aclocal.m4: Ditto.
        * m32r/aclocal.m4: Ditto.
        * m68hc11/aclocal.m4: Ditto.
        * m68k/aclocal.m4: Ditto.
        * mcore/aclocal.m4: Ditto.
        * mips/aclocal.m4: Ditto.
        * mn10200/aclocal.m4: Ditto.
        * mn10300/aclocal.m4: Ditto.
        * mt/aclocal.m4: Ditto.
        * pa/aclocal.m4: Ditto.
        * rs6000/aclocal.m4: Ditto.
        * sparc/aclocal.m4: Ditto.
        * sparc/libsys/aclocal.m4: Ditto.
        * xstormy16/aclocal.m4: Ditto.
---
 libgloss/acinclude.m4 | 62 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 libgloss/acinclude.m4

(limited to 'libgloss/acinclude.m4')

diff --git a/libgloss/acinclude.m4 b/libgloss/acinclude.m4
new file mode 100644
index 000000000..cdd34b6f0
--- /dev/null
+++ b/libgloss/acinclude.m4
@@ -0,0 +1,62 @@
+# FIXME: We temporarily define our own version of AC_PROG_CC.  This is
+# copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
+# are probably using a cross compiler, which will not be able to fully
+# link an executable.  This should really be fixed in autoconf
+# itself.
+
+AC_DEFUN([LIB_AC_PROG_CC_GNU],
+[AC_CACHE_CHECK(whether we are using GNU C, ac_cv_prog_gcc,
+[dnl The semicolon is to pacify NeXT's syntax-checking cpp.
+cat > conftest.c <<EOF
+#ifdef __GNUC__
+  yes;
+#endif
+EOF
+if AC_TRY_COMMAND(${CC-cc} -E conftest.c) | egrep yes >/dev/null 2>&1; then
+  ac_cv_prog_gcc=yes
+else
+  ac_cv_prog_gcc=no
+fi])])
+
+AC_DEFUN([LIB_AM_PROG_AS],
+[# By default we simply use the C compiler to build assembly code.
+AC_REQUIRE([LIB_AC_PROG_CC])
+test "${CCAS+set}" = set || CCAS=$CC
+test "${CCASFLAGS+set}" = set || CCASFLAGS=$CFLAGS
+AC_ARG_VAR([CCAS],      [assembler compiler command (defaults to CC)])
+AC_ARG_VAR([CCASFLAGS], [assembler compiler flags (defaults to CFLAGS)])
+])
+
+AC_DEFUN([LIB_AC_PROG_CC],
+[AC_BEFORE([$0], [AC_PROG_CPP])dnl
+AC_CHECK_PROG(CC, gcc, gcc)
+_AM_DEPENDENCIES(CC)
+if test -z "$CC"; then
+  AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
+  test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
+fi
+
+LIB_AC_PROG_CC_GNU
+
+if test $ac_cv_prog_gcc = yes; then
+  GCC=yes
+dnl Check whether -g works, even if CFLAGS is set, in case the package
+dnl plays around with CFLAGS (such as to build both debugging and
+dnl normal versions of a library), tasteless as that idea is.
+  ac_test_CFLAGS="${CFLAGS+set}"
+  ac_save_CFLAGS="$CFLAGS"
+  CFLAGS=
+  _AC_PROG_CC_G
+  if test "$ac_test_CFLAGS" = set; then
+    CFLAGS="$ac_save_CFLAGS"
+  elif test $ac_cv_prog_cc_g = yes; then
+    CFLAGS="-g -O2"
+  else
+    CFLAGS="-O2"
+  fi
+else
+  GCC=
+  test "${CFLAGS+set}" = set || CFLAGS="-g"
+fi
+])
+
-- 
cgit v1.2.3