Use DrawManager for Image/UV Editor

This project moves the current UV/Image editor drawing to the draw manager.
Why would we do this:

**Performance**:

Current implementation would draw each texel per time. Multiple texels could be
drawn per pixel what would overwrite the previous result. You can notice this
when working with large textures. Repeat image drawing made this visible by
drawing for a small period of time and stop drawing the rest. Now the rendering
is fast and all repeated images are drawn.

**Alpha drawing**:

Current implementation would draw directly in display space. Giving incorrect
results when displaying alpha transparent images.
This addresses {T52680}, {T74709}, {T79518}
The image editor now can show emission only colors. See {D8234} for
examples.

**Current Limitations**

Using images that are larger than supported by your GPU are resized (eg larger
than 16000x16000 are resized to 8k). This leaves some blurring artifacts. It is
a low priority to add support back of displaying individual pixels of huge
images. There is a design task {T80113} with more detail.

**Implementation overview**
Introduced an Image Engine in the draw module. this engine is responsible for
drawing the texture in the main area of the UV/Image editor. The overlay engine
has a edit_uv overlay which is responsible to draw the UV's, shadows and
overlays specifically for the UV Image editor. The background + checker pattern
is drawn by the overlay_background.

The patch will allow us to share overlays between the 3d viewport and UV/Image
editor more easily. In most cases we just need to switch the `pos` with the `u`
attribute in the vertex shader.

The project can be activated in the user preferences as experimental features.
In a later commit this will be reversed.

Reviewed By: Clément Foucault

Differential Revision: https://developer.blender.org/D8234

2 files changed, 122 insertions, 0 deletions

diff --git a/source/blender/draw/engines/image/shaders/engine_image_frag.glsl b/source/blender/draw/engines/image/shaders/engine_image_frag.glsl
new file mode 100644
index 00000000000..5c5d9362dfc
--- /dev/null
+++ b/source/blender/draw/engines/image/shaders/engine_image_frag.glsl
@@ -0,0 +1,91 @@
+#pragma BLENDER_REQUIRE(common_colormanagement_lib.glsl)
+
+/* Keep in sync with image_engine.c */
+#define SIMA_DRAW_FLAG_SHOW_ALPHA (1 << 0)
+#define SIMA_DRAW_FLAG_APPLY_ALPHA (1 << 1)
+#define SIMA_DRAW_FLAG_SHUFFLING (1 << 2)
+#define SIMA_DRAW_FLAG_DEPTH (1 << 3)
+#define SIMA_DRAW_FLAG_TILED (1 << 4)
+#define SIMA_DRAW_FLAG_DO_REPEAT (1 << 5)
+
+uniform sampler2DArray imageTileArray;
+uniform sampler1DArray imageTileData;
+uniform sampler2D imageTexture;
+
+uniform bool imgPremultiplied;
+uniform int drawFlags;
+uniform vec2 farNearDistances;
+uniform vec4 color;
+uniform vec4 shuffle;
+
+#define FAR_DISTANCE farNearDistances.x
+#define NEAR_DISTANCE farNearDistances.y
+
+in vec2 uvs;
+
+out vec4 fragColor;
+
+/* TODO(fclem) deduplicate code.  */
+bool node_tex_tile_lookup(inout vec3 co, sampler2DArray ima, sampler1DArray map)
+{
+  vec2 tile_pos = floor(co.xy);
+
+  if (tile_pos.x < 0 || tile_pos.y < 0 || tile_pos.x >= 10) {
+    return false;
+  }
+
+  float tile = 10.0 * tile_pos.y + tile_pos.x;
+  if (tile >= textureSize(map, 0).x) {
+    return false;
+  }
+
+  /* Fetch tile information. */
+  float tile_layer = texelFetch(map, ivec2(tile, 0), 0).x;
+  if (tile_layer < 0.0) {
+    return false;
+  }
+
+  vec4 tile_info = texelFetch(map, ivec2(tile, 1), 0);
+
+  co = vec3(((co.xy - tile_pos) * tile_info.zw) + tile_info.xy, tile_layer);
+  return true;
+}
+
+void main()
+{
+  vec4 tex_color;
+  /* Read texture */
+  if ((drawFlags & SIMA_DRAW_FLAG_TILED) != 0) {
+    vec3 co = vec3(uvs, 0.0);
+    if (node_tex_tile_lookup(co, imageTileArray, imageTileData)) {
+      tex_color = texture(imageTileArray, co);
+    }
+    else {
+      tex_color = vec4(1.0, 0.0, 1.0, 1.0);
+    }
+  }
+  else {
+    vec2 uvs_clamped = ((drawFlags & SIMA_DRAW_FLAG_DO_REPEAT) != 0) ?
+                           fract(uvs) :
+                           clamp(uvs, vec2(0.0), vec2(1.0));
+    tex_color = texture(imageTexture, uvs_clamped);
+  }
+
+  if ((drawFlags & SIMA_DRAW_FLAG_APPLY_ALPHA) != 0) {
+    if (!imgPremultiplied && tex_color.a != 0.0 && tex_color.a != 1.0) {
+      tex_color.rgb *= tex_color.a;
+    }
+  }
+  if ((drawFlags & SIMA_DRAW_FLAG_DEPTH) != 0) {
+    tex_color = smoothstep(FAR_DISTANCE, NEAR_DISTANCE, tex_color);
+  }
+
+  if ((drawFlags & SIMA_DRAW_FLAG_SHUFFLING) != 0) {
+    tex_color = color * dot(tex_color, shuffle);
+  }
+  if ((drawFlags & SIMA_DRAW_FLAG_SHOW_ALPHA) == 0) {
+    tex_color.a = 1.0;
+  }
+
+  fragColor = tex_color;
+}
diff --git a/source/blender/draw/engines/image/shaders/engine_image_vert.glsl b/source/blender/draw/engines/image/shaders/engine_image_vert.glsl
new file mode 100644
index 00000000000..3f1fb154d44
--- /dev/null
+++ b/source/blender/draw/engines/image/shaders/engine_image_vert.glsl
@@ -0,0 +1,31 @@
+#pragma BLENDER_REQUIRE(common_view_lib.glsl)
+
+#define SIMA_DRAW_FLAG_DO_REPEAT (1 << 5)
+
+uniform int drawFlags;
+
+in vec3 pos;
+out vec2 uvs;
+
+void main()
+{
+  /* `pos` contains the coordinates of a quad (-1..1). but we need the coordinates of an image
+   * plane (0..1) */
+  vec3 image_pos = pos * 0.5 + 0.5;
+
+  if ((drawFlags & SIMA_DRAW_FLAG_DO_REPEAT) != 0) {
+    gl_Position = vec4(pos.xy, 0.0, 1.0);
+    uvs = point_view_to_object(image_pos).xy;
+  }
+  else {
+    vec3 world_pos = point_object_to_world(image_pos);
+    vec4 position = point_world_to_ndc(world_pos);
+    /* Move drawn pixels to the front. In the overlay engine the depth is used
+     * to detect if a transparency texture or the background color should be drawn.
+     * Vertices are between 0.0 and 0.2, Edges between 0.2 and 0.4
+     * actual pixels are at 0.75, 1.0 is used for the background. */
+    position.z = 0.75;
+    gl_Position = position;
+    uvs = world_pos.xy;
+  }
+}