Re-add the CloudSync functionalityCURA-9146_account_sync

It got removed in the marketplace upgrade.

CURA-9146

2 files changed, 268 insertions, 0 deletions

diff --git a/plugins/Marketplace/resources/qml/CompatibilityDialog.qml b/plugins/Marketplace/resources/qml/CompatibilityDialog.qml
new file mode 100644
index 0000000000..2e8595c811
--- /dev/null
+++ b/plugins/Marketplace/resources/qml/CompatibilityDialog.qml
@@ -0,0 +1,154 @@
+// Copyright (c) 2022 Ultimaker B.V.
+// Marketplace is released under the terms of the LGPLv3 or higher.
+
+import QtQuick 2.10
+import QtQuick.Window 2.2
+import QtQuick.Controls 2.3
+
+import UM 1.1 as UM
+import Cura 1.6 as Cura
+
+
+UM.Dialog
+{
+    visible: true
+    title: catalog.i18nc("@title", "Changes from your account")
+    width: UM.Theme.getSize("popup_dialog").width
+    height: UM.Theme.getSize("popup_dialog").height
+    minimumWidth: width
+    maximumWidth: minimumWidth
+    minimumHeight: height
+    maximumHeight: minimumHeight
+    margin: 0
+
+    property string actionButtonText: subscribedPackagesModel.hasIncompatiblePackages && !subscribedPackagesModel.hasCompatiblePackages ? catalog.i18nc("@button", "Dismiss") : catalog.i18nc("@button", "Next")
+
+    Rectangle
+    {
+        id: root
+        anchors.fill: parent
+        color: UM.Theme.getColor("main_background")
+
+        UM.I18nCatalog
+        {
+            id: catalog
+            name: "cura"
+        }
+
+        ScrollView
+        {
+            width: parent.width
+            height: parent.height - nextButton.height - nextButton.anchors.margins * 2 // We want some leftover space for the button at the bottom
+            clip: true
+
+            Column
+            {
+                anchors.fill: parent
+                anchors.margins: UM.Theme.getSize("default_margin").width
+
+                // Compatible packages
+                Label
+                {
+                    font: UM.Theme.getFont("default")
+                    text: catalog.i18nc("@label", "The following packages will be added:")
+                    visible: subscribedPackagesModel.hasCompatiblePackages
+                    color: UM.Theme.getColor("text")
+                    height: contentHeight + UM.Theme.getSize("default_margin").height
+                }
+                Repeater
+                {
+                    model: subscribedPackagesModel
+                    Component
+                    {
+                        Item
+                        {
+                            width: parent.width
+                            property int lineHeight: 60
+                            visible: model.is_compatible
+                            height: visible ? (lineHeight + UM.Theme.getSize("default_margin").height) : 0 // We only show the compatible packages here
+                            Image
+                            {
+                                id: packageIcon
+                                source: model.icon_url || "../../images/placeholder.svg"
+                                height: lineHeight
+                                width: height
+                                sourceSize.height: height
+                                sourceSize.width: width
+                                mipmap: true
+                                fillMode: Image.PreserveAspectFit
+                            }
+                            Label
+                            {
+                                text: model.display_name
+                                font: UM.Theme.getFont("medium_bold")
+                                anchors.left: packageIcon.right
+                                anchors.leftMargin: UM.Theme.getSize("default_margin").width
+                                anchors.verticalCenter: packageIcon.verticalCenter
+                                color: UM.Theme.getColor("text")
+                                elide: Text.ElideRight
+                            }
+                        }
+                    }
+                }
+
+                // Incompatible packages
+                Label
+                {
+                    font: UM.Theme.getFont("default")
+                    text: catalog.i18nc("@label", "The following packages can not be installed because of an incompatible Cura version:")
+                    visible: subscribedPackagesModel.hasIncompatiblePackages
+                    color: UM.Theme.getColor("text")
+                    height: contentHeight + UM.Theme.getSize("default_margin").height
+                }
+                Repeater
+                {
+                    model: subscribedPackagesModel
+                    Component
+                    {
+                        Item
+                        {
+                            width: parent.width
+                            property int lineHeight: 60
+                            visible: !model.is_compatible && !model.is_dismissed
+                            height: visible ? (lineHeight + UM.Theme.getSize("default_margin").height) : 0 // We only show the incompatible packages here
+                            Image
+                            {
+                                id: packageIcon
+                                source: model.icon_url || "../../images/placeholder.svg"
+                                height: lineHeight
+                                width: height
+                                sourceSize.height: height
+                                sourceSize.width: width
+                                mipmap: true
+                                fillMode: Image.PreserveAspectFit
+                            }
+                            Label
+                            {
+                                text: model.display_name
+                                font: UM.Theme.getFont("medium_bold")
+                                anchors.left: packageIcon.right
+                                anchors.leftMargin: UM.Theme.getSize("default_margin").width
+                                anchors.verticalCenter: packageIcon.verticalCenter
+                                color: UM.Theme.getColor("text")
+                                elide: Text.ElideRight
+                            }
+                        }
+                    }
+                }
+            }
+
+        } // End of ScrollView
+
+        Cura.PrimaryButton
+        {
+            id: nextButton
+            anchors.bottom: parent.bottom
+            anchors.right: parent.right
+            anchors.margins: UM.Theme.getSize("default_margin").height
+            text: actionButtonText
+            onClicked: accept()
+            leftPadding: UM.Theme.getSize("dialog_primary_button_padding").width
+            rightPadding: UM.Theme.getSize("dialog_primary_button_padding").width
+        }
+    }
+}
diff --git a/plugins/Marketplace/resources/qml/MarketplaceLicenseDialog.qml b/plugins/Marketplace/resources/qml/MarketplaceLicenseDialog.qml
new file mode 100644
index 0000000000..b4f1ef3dea
--- /dev/null
+++ b/plugins/Marketplace/resources/qml/MarketplaceLicenseDialog.qml
@@ -0,0 +1,114 @@
+// Copyright (c) 2021 Ultimaker B.V.
+// Marketplace is released under the terms of the LGPLv3 or higher.
+
+import QtQuick 2.10
+import QtQuick.Window 2.2
+import QtQuick.Controls 2.3
+import QtQuick.Layouts 1.3
+
+import UM 1.1 as UM
+import Cura 1.6 as Cura
+
+UM.Dialog
+{
+    id: licenseDialog
+    title: licenseModel.dialogTitle
+    Component.onCompleted:
+    {
+        for(var p in licenseModel)
+            console.log(p + ": " + item[p]);
+    }
+
+    minimumWidth: UM.Theme.getSize("license_window_minimum").width
+    minimumHeight: UM.Theme.getSize("license_window_minimum").height
+    width: minimumWidth
+    height: minimumHeight
+    backgroundColor: UM.Theme.getColor("main_background")
+    margin: screenScaleFactor * 10
+
+    ColumnLayout
+    {
+        anchors.fill: parent
+        spacing: UM.Theme.getSize("thick_margin").height
+
+        UM.I18nCatalog{id: catalog; name: "cura"}
+
+        Label
+        {
+            id: licenseHeader
+            Layout.fillWidth: true
+            text: catalog.i18nc("@label", "You need to accept the license to install the package")
+            color: UM.Theme.getColor("text")
+            wrapMode: Text.Wrap
+            renderType: Text.NativeRendering
+        }
+
+        Row {
+            id: packageRow
+
+            Layout.fillWidth: true
+            height: childrenRect.height
+            spacing: UM.Theme.getSize("default_margin").width
+            leftPadding: UM.Theme.getSize("narrow_margin").width
+
+            Image
+            {
+                id: icon
+                width: 30 * screenScaleFactor
+                height: width
+                sourceSize.width: width
+                sourceSize.height: height
+                fillMode: Image.PreserveAspectFit
+                source: licenseModel.iconUrl || "../../images/placeholder.svg"
+                mipmap: true
+            }
+
+            Label
+            {
+                id: packageName
+                text: licenseModel.packageName
+                color: UM.Theme.getColor("text")
+                font.bold: true
+                anchors.verticalCenter: icon.verticalCenter
+                height: contentHeight
+                wrapMode: Text.Wrap
+                renderType: Text.NativeRendering
+            }
+
+
+        }
+
+        Cura.ScrollableTextArea
+        {
+
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+            anchors.topMargin: UM.Theme.getSize("default_margin").height
+
+            textArea.text: licenseModel.licenseText
+            textArea.readOnly: true
+        }
+
+    }
+    rightButtons:
+    [
+        Cura.PrimaryButton
+        {
+            leftPadding: UM.Theme.getSize("dialog_primary_button_padding").width
+            rightPadding: UM.Theme.getSize("dialog_primary_button_padding").width
+
+            text: licenseModel.acceptButtonText
+            onClicked: { handler.onLicenseAccepted() }
+        }
+    ]
+
+    leftButtons:
+    [
+        Cura.SecondaryButton
+        {
+            id: declineButton
+            text: licenseModel.declineButtonText
+            onClicked: { handler.onLicenseDeclined() }
+        }
+    ]
+}