blob: 58bf736575ea223e0839e08fda3d212d66e55190 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
|
// Copyright (c) 2022 Ultimaker B.V.
// Cura is released under the terms of the LGPLv3 or higher.
import QtQuick 2.7
import QtQuick.Controls 2.4
import QtQuick.Layouts 1.3
import UM 1.4 as UM
import Cura 1.0 as Cura
// This element contains all the elements the user needs to create a printjob from the
// model(s) that is(are) on the buildplate. Mainly the button to start/stop the slicing
// process and a progress bar to see the progress of the process.
Column
{
id: widget
spacing: UM.Theme.getSize("thin_margin").height
UM.I18nCatalog
{
id: catalog
name: "cura"
}
property real progress: UM.Backend.progress
property int backendState: UM.Backend.state
// As the collection of settings to send to the engine might take some time, we have an extra value to indicate
// That the user pressed the button but it's still waiting for the backend to acknowledge that it got it.
property bool waitingForSliceToStart: false
onBackendStateChanged: waitingForSliceToStart = false
function sliceOrStopSlicing()
{
if (widget.backendState == UM.Backend.NotStarted)
{
widget.waitingForSliceToStart = true
CuraApplication.backend.forceSlice()
}
else
{
widget.waitingForSliceToStart = false
CuraApplication.backend.stopSlicing()
}
}
Label
{
id: autoSlicingLabel
width: parent.width
visible: progressBar.visible
text: catalog.i18nc("@label:PrintjobStatus", "Slicing...")
color: UM.Theme.getColor("text")
font: UM.Theme.getFont("default")
renderType: Text.NativeRendering
}
Item
{
id: unableToSliceMessage
width: parent.width
visible: widget.backendState == UM.Backend.Error
height: warningIcon.height
UM.StatusIcon
{
id: warningIcon
anchors.verticalCenter: parent.verticalCenter
width: visible ? UM.Theme.getSize("section_icon").width : 0
height: width
status: UM.StatusIcon.Status.WARNING
}
Label
{
id: label
anchors.left: warningIcon.right
anchors.right: parent.right
anchors.verticalCenter: parent.verticalCenter
anchors.leftMargin: UM.Theme.getSize("default_margin").width
text: catalog.i18nc("@label:PrintjobStatus", "Unable to slice")
color: UM.Theme.getColor("text")
font: UM.Theme.getFont("default")
renderType: Text.NativeRendering
wrapMode: Text.WordWrap
}
}
// Progress bar, only visible when the backend is in the process of slice the printjob
UM.ProgressBar
{
id: progressBar
width: parent.width
height: UM.Theme.getSize("progressbar").height
value: progress
indeterminate: widget.backendState == UM.Backend.NotStarted
visible: (widget.backendState == UM.Backend.Processing || (prepareButtons.autoSlice && widget.backendState == UM.Backend.NotStarted))
}
Item
{
id: prepareButtons
// Get the current value from the preferences
property bool autoSlice: UM.Preferences.getValue("general/auto_slice")
// Disable the slice process when
width: parent.width
height: UM.Theme.getSize("action_button").height
visible: !autoSlice
Cura.PrimaryButton
{
id: sliceButton
fixedWidthMode: true
height: parent.height
anchors.right: parent.right
anchors.left: parent.left
text: widget.waitingForSliceToStart ? catalog.i18nc("@button", "Processing"): catalog.i18nc("@button", "Slice")
tooltip: catalog.i18nc("@label", "Start the slicing process")
hoverEnabled: !widget.waitingForSliceToStart
enabled: widget.backendState != UM.Backend.Error && !widget.waitingForSliceToStart
visible: widget.backendState == UM.Backend.NotStarted || widget.backendState == UM.Backend.Error
onClicked: {
sliceOrStopSlicing()
}
}
Cura.SecondaryButton
{
id: cancelButton
fixedWidthMode: true
height: parent.height
anchors.left: parent.left
anchors.right: parent.right
text: catalog.i18nc("@button", "Cancel")
enabled: sliceButton.enabled
visible: !sliceButton.visible
onClicked: {
sliceOrStopSlicing()
}
}
}
// React when the user changes the preference of having the auto slice enabled
Connections
{
target: UM.Preferences
function onPreferenceChanged(preference)
{
if (preference !== "general/auto_slice")
{
return;
}
var autoSlice = UM.Preferences.getValue("general/auto_slice")
if(prepareButtons.autoSlice != autoSlice)
{
prepareButtons.autoSlice = autoSlice
if(autoSlice)
{
CuraApplication.backend.forceSlice()
}
}
}
}
// Shortcut for "slice/stop"
Action
{
shortcut: "Ctrl+P"
onTriggered:
{
if (sliceButton.enabled)
{
sliceOrStopSlicing()
}
}
}
}
|