blob: 9ddbb06dfcf581fd67f27bf04f04044a714f48cd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
|
# Main application in qt.
ROOT_DIR = ..
DEPENDENCIES = map render gui routing search storage indexer graphics platform anim geometry coding base \
freetype expat fribidi tomcrypt jansson protobuf osrm stats_client minizip succinct
drape {
DEPENDENCIES *= drape_frontend drape
}
include($$ROOT_DIR/common.pri)
TARGET = MAPS.ME
TEMPLATE = app
CONFIG += warn_on
QT *= core widgets gui opengl
win32* {
LIBS += -lopengl32 -lws2_32 -lshell32 -liphlpapi
RC_FILE = res/windows.rc
win32-msvc*: LIBS += -lwlanapi
win32-g++: LIBS += -lpthread
}
win32*|linux* {
QT *= network
}
linux* {
isEmpty(PREFIX):PREFIX = /usr
DEFINES += INSTALL_PREFIX=$$(PREFIX)
BINDIR = $$PREFIX/bin
DATADIR = $$PREFIX/share/mapsme
FONTSDIR = /usr/share/fonts/truetype/mapsme/
target.path = $$BINDIR
desktop.path = /usr/share/applications/
desktop.files += res/$${TARGET}.desktop
INSTALLS += target desktop
}
macx-* {
LIBS *= "-framework CoreLocation" "-framework Foundation" "-framework CoreWLAN" \
"-framework QuartzCore" "-framework IOKit" "-framework SystemConfiguration"
ICON = res/mac.icns
PLIST_FILE = Info.plist
# path to original plist, which will be processed by qmake and later by us
QMAKE_INFO_PLIST = res/$${PLIST_FILE}
# fix version directly in bundle's Info.plist
PLIST_PATH = $${DESTDIR}/$${TARGET}.app/Contents/$${PLIST_FILE}
QMAKE_POST_LINK = $${IN_PWD}/../tools/unix/process_plist.sh $${IN_PWD}/.. $$VERSION_MAJOR $$VERSION_MINOR $$PLIST_PATH
DATADIR = Contents/Resources
FONTSDIR = $$DATADIR
}
OTHER_RES.path = $$DATADIR
OTHER_RES.files = ../data/copyright.html ../data/eula.html ../data/welcome.html \
../data/countries.txt \
../data/languages.txt ../data/categories.txt \
../data/packed_polygons.bin res/logo.png
CLASSIFICATOR_RES.path = $$DATADIR
CLASSIFICATOR_RES.files = ../data/classificator.txt \
../data/types.txt \
../data/drules_proto.bin
MDPI_SKIN_RES.path = $$DATADIR/resources-mdpi
MDPI_SKIN_RES.files = ../data/resources-mdpi/basic.skn ../data/resources-mdpi/symbols.png
XHDPI_SKIN_RES.path = $$DATADIR/resources-xhdpi
XHDPI_SKIN_RES.files = ../data/resources-xhdpi/basic.skn ../data/resources-xhdpi/symbols.png
FONT_RES.path = $$FONTSDIR
FONT_RES.files = ../data/00_roboto_regular.ttf \
../data/01_dejavusans.ttf \
../data/02_droidsans-fallback.ttf \
../data/03_jomolhari-id-a3d.ttf \
../data/04_padauk.ttf \
../data/05_khmeros.ttf \
../data/06_code2000.ttf
OTHER_RES.files += ../data/fonts_blacklist.txt \
../data/fonts_whitelist.txt \
../data/unicode_blocks.txt
MWM_RES.path = $$DATADIR
MWM_RES.files = ../data/World.mwm ../data/WorldCoasts.mwm
ALL_RESOURCES = OTHER_RES CLASSIFICATOR_RES MDPI_SKIN_RES XHDPI_SKIN_RES FONT_RES MWM_RES
linux* {
INSTALLS += $$ALL_RESOURCES
}
macx-* {
QMAKE_BUNDLE_DATA += $$ALL_RESOURCES
}
SOURCES += \
main.cpp \
mainwindow.cpp \
draw_widget.cpp \
proxystyle.cpp \
slider_ctrl.cpp \
about.cpp \
info_dialog.cpp \
preferences_dialog.cpp \
search_panel.cpp \
update_dialog.cpp \
CONFIG(drape){
SOURCES += \
drape_surface.cpp \
qtoglcontext.cpp \
qtoglcontextfactory.cpp \
}
HEADERS += \
mainwindow.hpp \
widgets.hpp \
draw_widget.hpp \
proxystyle.hpp \
slider_ctrl.hpp \
about.hpp \
info_dialog.hpp \
preferences_dialog.hpp \
search_panel.hpp \
update_dialog.hpp \
CONFIG(drape){
HEADERS += \
drape_surface.hpp \
qtoglcontext.hpp \
qtoglcontextfactory.hpp \
}
RESOURCES += res/resources.qrc
|
