mcs/ilasm/tests/test-seh-a.il


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

//
// Test catch and finally blocks
//
// Author(s):
//  Jackson Harper (Jackson@LatitudeGeo.com)
//
// (C) 2003 Jackson Harper, All rights reserved
//

.assembly extern mscorlib { }
.assembly extern System { }
.assembly 'test-seh-a' { }


.class public T {

        .field private static int32 exc_caught
        .field private static int32 fin_caught
  
        .method public static specialname void .cctor ()
        {
                ldc.i4.0
                stsfld int32 T::exc_caught

                ldc.i4.0
                stsfld int32 T::fin_caught

                ret
        }

        .method public static int32 Main ()
        {
                .entrypoint

                .try {
                        .try {
                                ldstr "#jibba!!jabba"
                                newobj void [System]System.Uri::.ctor (string)
                                leave outer
                        } catch [mscorlib]System.Exception {
                                ldc.i4.1
                                stsfld int32 T::exc_caught
                                leave outer
                        }
                        leave outer
                 } finally {
                        ldc.i4.1
                        stsfld int32 T::fin_caught
                        endfinally
                 }
           

        outer:
                ldsfld int32 T::exc_caught
                brfalse fail

                ldsfld int32 T::fin_caught
                brfalse fail

        pass:
                ldstr "PASS"
                call void [mscorlib]System.Console::WriteLine (string)
                ldc.i4.0
                ret

        fail:
                ldstr "FAIL"
                call void [mscorlib]System.Console::WriteLine (string)
                ldc.i4.1
                ret

        }

}