path: root/configure.in

AC_INIT([monodevelop], 0.15, [monodevelop-list@lists.ximian.com])
AC_PREREQ(2.53)
AM_INIT_AUTOMAKE([1.9 tar-ustar])
AM_MAINTAINER_MODE

AC_PROG_INTLTOOL([0.25])

ASSEMBLY_VERSION=0.15.0.0

AC_PATH_PROG(MONO, mono)
AC_PATH_PROG(MCS, gmcs)

if test "x$MONO" = "x" ; then
	AC_MSG_ERROR([Can't find "mono" in your PATH])
fi

if test "x$MCS" = "x" ; then
  AC_MSG_ERROR([Can't find "gmcs" in your PATH])
fi
AC_SUBST(PATH)
AC_SUBST(LD_LIBRARY_PATH)

dnl Add MD's mimetypes to mime and desktop databases
AC_PATH_PROG(UPDATE_MIME_DB, update-mime-database, no)
if test "x$UPDATE_MIME_DB" = "xno"; then
   AC_MSG_ERROR([You need to install update-mime-database])
fi
AC_SUBST(UPDATE_MIME_DB)

AC_PATH_PROG(UPDATE_DESKTOP_DB, update-desktop-database, no)
if test "x$UPDATE_DESKTOP_DB" = "xno"; then
   AC_MSG_ERROR([You need to install update-desktop-database])
fi
AC_SUBST(UPDATE_DESKTOP_DB)

dnl Find pkg-config
AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
if test "x$PKG_CONFIG" = "xno"; then
        AC_MSG_ERROR([You need to install pkg-config])
fi

MONO_REQUIRED_VERSION=1.1.10
PKG_CHECK_MODULES(UNMANAGED_DEPENDENCIES_MONO,mono >= $MONO_REQUIRED_VERSION, has_mono=true, has_mono=false)
PKG_CHECK_MODULES(UNMANAGED_DEPENDENCIES_MINT,mint >= $MONO_REQUIRED_VERSION, has_mint=true, has_mint=false)

if test "x$has_mono" = "xfalse"; then
  if test "x$has_mint" = "xfalse"; then
      AC_MSG_ERROR([Please install mono version $MONO_REQUIRED_VERSION or later to install MonoDevelop.
Please see http://www.mono-project.org/ to download latest mono sources or packages])
  fi
fi

if test "x$has_mono" = "xtrue"; then
    if test `uname -s` = "Darwin"; then
	AC_PATH_PROG(RUNTIME, mono, no)
	AC_PATH_PROG(CSC, gmcs, no)
	LIB_PREFIX=
	LIB_SUFFIX=.dylib
    else
	AC_PATH_PROG(RUNTIME, mono, no)
	AC_PATH_PROG(CSC, gmcs, no)
	LIB_PREFIX=.so
	LIB_SUFFIX=
    fi
else
    if test "x$has_mint" = "xtrue"; then
	AC_PATH_PROG(RUNTIME, mint, no)
	AC_PATH_PROG(CSC, gmcs, no)
	LIB_PREFIX=.so
	LIB_SUFFIX=
    fi
fi


dnl hard dependencies
GTKSHARP_REQUIRED_VERSION=2.8.0
GTKSOURCEVIEWSHARP_REQUIRED_VERSION=0.10
GECKOSHARP_REQUIRED_VERSION=0.10
MONODOC_REQUIRED_VERSION=1.0

PKG_CHECK_MODULES(GLIB_SHARP, glib-sharp-2.0 >= $GTKSHARP_REQUIRED_VERSION)
AC_SUBST(GLIB_SHARP_LIBS)
PKG_CHECK_MODULES(GTK_SHARP, gtk-sharp-2.0 >= $GTKSHARP_REQUIRED_VERSION)
AC_SUBST(GTK_SHARP_LIBS)
PKG_CHECK_MODULES(GNOME_SHARP, gnome-sharp-2.0 >= $GTKSHARP_REQUIRED_VERSION)
AC_SUBST(GNOME_SHARP_LIBS)
PKG_CHECK_MODULES(GNOME_VFS_SHARP, gnome-vfs-sharp-2.0 >= $GTKSHARP_REQUIRED_VERSION)
AC_SUBST(GNOME_VFS_SHARP_LIBS)
PKG_CHECK_MODULES(GLADE_SHARP, glade-sharp-2.0 >= $GTKSHARP_REQUIRED_VERSION)
AC_SUBST(GLADE_SHARP_LIBS)
PKG_CHECK_MODULES(GCONF_SHARP, gconf-sharp-2.0 >= $GTKSHARP_REQUIRED_VERSION)
AC_SUBST(GCONF_SHARP_LIBS)
PKG_CHECK_MODULES(GTKHTML_SHARP, gtkhtml-sharp-2.0 >= $GTKSHARP_REQUIRED_VERSION)
AC_SUBST(GTKHTML_SHARP_LIBS)
PKG_CHECK_MODULES(GTKSOURCEVIEW_SHARP, gtksourceview-sharp-2.0 >= $GTKSOURCEVIEWSHARP_REQUIRED_VERSION)
AC_SUBST(GTKSOURCEVIEW_SHARP_LIBS)
PKG_CHECK_MODULES(GECKO_SHARP, gecko-sharp-2.0 >= $GECKOSHARP_REQUIRED_VERSION)
AC_SUBST(GECKO_SHARP_LIBS)
PKG_CHECK_MODULES(MONODOC, monodoc >= $MONODOC_REQUIRED_VERSION)
AC_SUBST(MONODOC_LIBS)
PKG_CHECK_MODULES(MONO_CAIRO, mono-cairo >= 1.2)
AC_SUBST(MONO_CAIRO_LIBS)

gtksharp_prefix="`$PKG_CONFIG --variable=prefix gtk-sharp-2.0`"
AC_SUBST(gtksharp_prefix)

dnl deal with the mono debugger
MONO_DEBUGGER_REQUIRED_VERSION=0.9
AC_ARG_ENABLE(debugger,
   AC_HELP_STRING([--enable-debugger],
                   [enable support for the Mono Debugger [default=no]]),
   [PKG_CHECK_MODULES(MONO_DEBUGGER, mono-debugger >= $MONO_DEBUGGER_REQUIRED_VERSION,
				     enable_debugger=yes, enable_debugger=no)],
   enable_debugger=no)
 AM_CONDITIONAL(ENABLE_DEBUGGER, test x$enable_debugger = xyes)
 AC_SUBST(MONO_DEBUGGER_LIBS) 

if test "x$enable_debugger" = "xyes"; then
	AC_MSG_ERROR([The debugger add-in is not currently supported due to the API changes being done in the Mono debugger.])
fi


dnl java binding
dnl need to test for a java source to bytecode compiler
dnl and for ikvm
IKVM_REQUIRED_VERSION=0.10
AC_ARG_ENABLE(java,
	AC_HELP_STRING([--enable-java],
		[enable support for Java via ikvm [default=no]]),
		[PKG_CHECK_MODULES(IKVM, ikvm >= $IKVM_REQUIRED_VERSION, enable_java=yes, enable_java=no)],
		enable_java=no)
AM_CONDITIONAL(ENABLE_JAVA, test x$enable_java = xyes)

BOO_REQUIRED_VERSION=0.7.9.2659
AC_ARG_ENABLE(boo,
	AC_HELP_STRING([--enable-boo],
		[enable support for boo [default=no]]),
		[PKG_CHECK_MODULES(BOO, boo >= $BOO_REQUIRED_VERSION, enable_boo=yes, enable_boo=no)],
		enable_boo=no)

AM_CONDITIONAL(ENABLE_BOO, test x$enable_boo = xyes)
AC_SUBST(BOO_LIBS)

if test "x$enable_boo" = "xyes" ; then
	AC_PATH_PROG(BOOC, booc)
fi

NEMERLE_REQUIRED_VERSION=0.9.3.99
AC_ARG_ENABLE(nemerle,
	AC_HELP_STRING([--enable-nemerle],
		[enable support for Nemerle [default=no]]),
		[PKG_CHECK_MODULES(NEMERLE, nemerle >= $NEMERLE_REQUIRED_VERSION, enable_nemerle=yes, enable_nemerle=no)],
		enable_nemerle=no)

AM_CONDITIONAL(ENABLE_NEMERLE, test x$enable_nemerle = xyes)
AC_SUBST(NEMERLE_LIBS)

if test "x$enable_nemerle" = "xyes" ; then
	AC_PATH_PROG(NCC, ncc)
fi

AC_ARG_ENABLE(monoextensions,
	AC_HELP_STRING([--enable-monoextensions],
		[enable extensions for Mono development [default=yes]]),
	enable_monoextensions=${enableval}, enable_monoextensions=yes)

AM_CONDITIONAL(ENABLE_MONOEXTENSIONS, test x$enable_monoextensions = xyes)

AC_ARG_ENABLE(versioncontrol,
	AC_HELP_STRING([--enable-versioncontrol],
		[enable version control support [default=yes]]),
		enable_versioncontrol=${enableval}, enable_versioncontrol=yes)

AM_CONDITIONAL(ENABLE_VERSIONCONTROL, test x$enable_versioncontrol = xyes)

AC_ARG_ENABLE(subversion,
	AC_HELP_STRING([--enable-subversion],
		[enable Subversion support [default=no]]),
		enable_versioncontrol=yes, enable_subversion=no)

AM_CONDITIONAL(ENABLE_SUBVERSION, test x$enable_subversion = xyes)

dnl *********************************************************
dnl *** The following hunk of script-fu is to detect the  ***
dnl *** available MonoQuery database providers...         ***
dnl *********************************************************
AC_ARG_ENABLE(monoquery,
	AC_HELP_STRING([--enable-monoquery],
		[enable MonoQuery support [default=auto]]),
		enable_monoquery=${enableval}, enable_monoquery=yes)

SQL_PROVIDER_ATTRIBUTES="[[XmlInclude (typeof (FirebirdDbProvider))]\n\t[XmlInclude (typeof (OdbcDbProvider))]]"
monoquery_avail=0
enable_postgres=no
enable_mysql=no
enable_sqlite=no
enable_oracle=no
enable_sqlserv=no
enable_sybase=no

if test "x$enable_monoquery" = "xyes"; then
   monoquery_try_compile () {
      cat <<EOF | sed -e "s/\${Dbase}/${Dbase}/g" -e "s/\${Using}/${Using}/g" > myconftest.cs
using System;
using System.Data;
using System.Collections;

using ${Using};

namespace Autoconf.Try.Compile {
	public class Program {
		public static void Main (string [[]] args)
		{
			${Dbase}Connection connection = new ${Dbase}Connection ();
			connection.Open ();
		}
	}
}
EOF
      $CSC myconftest.cs -r:System.Data $ExtraDbAssemblies > /dev/null 2>&1
      if test $? -eq 0; then
	 my_ac_conftest_result="yes"
	 monoquery_avail=`expr $monoquery_avail + 1`
	 SQL_PROVIDER_ATTRIBUTES="[$SQL_PROVIDER_ATTRIBUTES\n\t[XmlInclude (typeof (${Dbase}DbProvider))]]"
      else
         my_ac_conftest_result="no"
      fi
      rm -f myconftest.cs myconftest.exe
   }
   
   AC_MSG_CHECKING([for PostgreSQL support])
   ExtraDbAssemblies="-r:Npgsql"
   Using="Npgsql"
   Dbase="Npgsql"
   monoquery_try_compile
   enable_postgres=$my_ac_conftest_result
   AC_MSG_RESULT($my_ac_conftest_result)
   
   AC_MSG_CHECKING([for MySQL support])
   ExtraDbAssemblies="-r:ByteFX.Data"
   Using="ByteFX.Data.MySqlClient"
   Dbase="MySql"
   monoquery_try_compile
   enable_mysql=$my_ac_conftest_result
   AC_MSG_RESULT($my_ac_conftest_result)
   
   AC_MSG_CHECKING([for SQLite support])
   ExtraDbAssemblies="-r:Mono.Data.SqliteClient"
   Using="Mono.Data.SqliteClient"
   Dbase="Sqlite"
   monoquery_try_compile
   enable_sqlite=$my_ac_conftest_result
   AC_MSG_RESULT($my_ac_conftest_result)
   
   AC_MSG_CHECKING([for Oracle support])
   ExtraDbAssemblies="-r:System.Data.OracleClient"
   Using="System.Data.OracleClient"
   Dbase="Oracle"
   monoquery_try_compile
   enable_oracle=$my_ac_conftest_result
   AC_MSG_RESULT($my_ac_conftest_result)
   
   AC_MSG_CHECKING([for SQL Server support])
   ExtraDbAssemblies=""
   Using="System.Data.SqlClient"
   Dbase="Sql"
   monoquery_try_compile
   enable_sqlserv=$my_ac_conftest_result
   AC_MSG_RESULT($my_ac_conftest_result)
   
   AC_MSG_CHECKING([for Sybase support])
   ExtraDbAssemblies="-r:Mono.Data.SybaseClient"
   Using="Mono.Data.SybaseClient"
   Dbase="Sybase"
   monoquery_try_compile
   enable_sybase=$my_ac_conftest_result
   AC_MSG_RESULT($my_ac_conftest_result)
   
   dnl If no providers are available, disable MonoQuery support
   if test $monoquery_avail -eq 0; then
      enable_monoquery="no"
   fi
fi

AM_CONDITIONAL(ENABLE_MONOQUERY, [test $enable_monoquery = yes])
AM_CONDITIONAL(ENABLE_POSTGRES, [test $enable_postgres = yes])
AM_CONDITIONAL(ENABLE_MYSQL, [test $enable_mysql = yes])
AM_CONDITIONAL(ENABLE_SQLITE, [test $enable_sqlite = yes])
AM_CONDITIONAL(ENABLE_ORACLE, [test $enable_oracle = yes])
AM_CONDITIONAL(ENABLE_SQLSERV, [test $enable_sqlserv = yes])
AM_CONDITIONAL(ENABLE_SYBASE, [test $enable_sybase = yes])

sed -e "s/@SQLProviderAttributes@/$SQL_PROVIDER_ATTRIBUTES/" \
    $srcdir/Extras/MonoQuery/MonoQuery/Gui/DbProviderCollection.cs.in \
    > $srcdir/Extras/MonoQuery/MonoQuery/Gui/DbProviderCollection.cs


dnl ASP.NET project addin
XSP_VERSION=0.1
XSP2_VERSION=0.2
AC_ARG_ENABLE(aspnet,
	AC_HELP_STRING([--enable-aspnet],
		[enable ASP.NET project support [default=no]]),
		enable_aspnet=yes, enable_aspnet=no)

if test "x$enable_aspnet" = "xyes"; then
	PKG_CHECK_MODULES(XSP, xsp >= $XSP_VERSION xsp-2 >= $XSP2_VERSION)
fi

AM_CONDITIONAL(ENABLE_ASPNET, [test x$enable_aspnet = xyes]) 

#We need to know where Mozilla is for launch scripts and possible for AspNetEdit
#Check pkg-config first
MOZILLA_HOME="`$PKG_CONFIG --variable=libdir mozilla-gtkmozembed`"
if !(test -n "$MOZILLA_HOME"); then
	MOZILLA_HOME="`$PKG_CONFIG --variable=libdir firefox-gtkmozembed`"
fi
if !(test -n "$MOZILLA_HOME"); then
	MOZILLA_HOME="`$PKG_CONFIG --variable=libdir xulrunner-gtkmozembed`"
fi

#if MOZILLA_HOME is still empty, try to detect without pkg_config
#(NOTE: any changes to this block should be kept in sync with the one in monodevelop.in)
if !(test -n "$MOZILLA_HOME"); then
	mozilla_script=`which mozilla 2> /dev/null`
	firefox_script=`which firefox 2> /dev/null`
	if test -n "$MOZILLA_FIVE_HOME"; then
		MOZILLA_HOME=$MOZILLA_FIVE_HOME
	elif grep GRE_PATH /etc/gre.d/*.conf > /dev/null 2>&1 ; then
		MOZILLA_HOME=$(grep -h GRE_PATH= /etc/gre.d/*.conf | cut -d '"' -f 2 -d = | head -n 1) #"
	elif test -n "$mozilla_script"  && grep "MOZILLA_FIVE_HOME=" $mozilla_script > /dev/null ; then
		MOZILLA_HOME=`grep "MOZILLA_FIVE_HOME=" $mozilla_script | cut -d '"' -f 2 | cut -d '=' -f 2`
	elif test -n "$firefox_script" ; then
		if grep "MOZILLA_FIVE_HOME=" $firefox_script > /dev/null ; then
			MOZILLA_HOME=`grep "MOZILLA_FIVE_HOME=" $firefox_script | cut -d '"' -f 2 | cut -d '=' -f 2`
		elif grep "MOZILLA_LIBDIR=" $firefox_script > /dev/null ; then
			MOZILLA_HOME=`grep "MOZILLA_LIBDIR=" $firefox_script | cut -d '"' -f 2 | cut -d '=' -f 2`
		elif grep "moz_libdir=" $firefox_script > /dev/null ; then
			MOZILLA_HOME=`grep "moz_libdir=" $firefox_script | cut -d '"' -f 2 | cut -d '=' -f 2`
		fi
	fi
	if test -z "$MOZILLA_HOME"; then
		if test "x$enable_aspnetedit" = "xyes"; then
			AC_MSG_ERROR([Cannot detect Mozilla library directory. AspNetEdit addin cannot be built.])
		else
			AC_MSG_WARN([Cannot detect Mozilla library directory. WelcomePage addin may not be able to function.])
		fi
	fi
fi
	
AC_SUBST(MOZILLA_HOME)

# ASP.NET visual designer addin
AC_ARG_ENABLE(aspnetedit,
	AC_HELP_STRING([--enable-aspnetedit],
		[enable ASP.NET visual designer support [default=no]]),
		enable_aspnetedit=yes, enable_aspnetedit=no)

if test "x$enable_aspnet" = "xno"; then
	enable_aspnetedit=no
	AC_MSG_WARN([Cannot enable AspNetEdit without ASP.NET project support.])
fi

if test "x$enable_aspnetedit" = "xyes"; then

	### Find out how we need to install the chrome -- the installation mechanism 
	### changed from FF 1.0 to FF 1.5
	AC_MSG_CHECKING([method of Mozilla extension installation])
	if test -f "$MOZILLA_HOME/chrome/installed-chrome.txt"; then
		MOZILLA_EXTENSION_TYPE="installedchrome"
		AC_MSG_RESULT([installed-chrome.txt])
	else
		MOZILLA_EXTENSION_TYPE="manifest"
		AC_MSG_RESULT([manifest file])
	fi
	
	AC_SUBST(MOZILLA_EXTENSION_TYPE)
	
	# get zip to create jar/xpi for chrome
	AC_PATH_PROG(ZIP, zip)
	if test "x$ZIP" = "x" ; then
		AC_MSG_ERROR([Can't find "zip" in your PATH])
	fi
fi

AM_CONDITIONAL(MOZILLA_EXTENSION_TYPE_TEXTFILE, test -f "$MOZILLA_HOME/chrome/installed-chrome.txt")
AM_CONDITIONAL(ENABLE_ASPNETEDIT, test x$enable_aspnetedit = xyes)

dnl C/C++ project addin
GCC_VERSION=4.1.2
CTAGS_VERSION=5.5
AC_ARG_ENABLE(c, AC_HELP_STRING([--enable-c], [enable C/C++ project support [default=no]]), enable_c=yes, enable_c=no)

if test "x$enable_c" = "xyes"; then
	AC_PATH_PROG(GCC, gcc)
	if test "x$GCC" = "x"; then
		AC_MSG_ERROR([Please install gcc version $GCC_VERSION or later.])
	fi

	AC_PATH_PROG(GPP, g++)
	if test "x$GPP" = "x"; then
		AC_MSG_WARN([Without g++ ($GCC_VERSION or later) you won't be able to compile C++ projects.])
	fi

	AC_PATH_PROG(CTAGS, ctags)
	if test "x$CTAGS" = "x"; then
		AC_MSG_WARN([Without ctags you won't get class pad and completion support for C/C++ projects.])
	fi
fi

AM_CONDITIONAL(ENABLE_C, [test x$enable_c = xyes])

AC_ARG_ENABLE(update-mimedb,
   AC_HELP_STRING([--disable-update-mimedb],
                   [disable the update-mime-database after install [default=no]]),,
    enable_update_mimedb=yes)
 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x$enable_update_mimedb = xyes)

AC_ARG_ENABLE(update-desktopdb,
   AC_HELP_STRING([--disable-update-desktopdb],
                  [disable the update-desktop-database after install [default=np]]),,
                  enable_update_desktopdb=yes)
   AM_CONDITIONAL(ENABLE_UPDATE_DESKTOPDB, test x$enable_update_desktopdb = xyes)

dnl Intl
ALL_LINGUAS="cs da de es fr ja pt_BR tr pl it zh_TW zh_CN ru sl_SI ca gl pt sv"
GETTEXT_PACKAGE=monodevelop
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package])
AM_GLIB_GNU_GETTEXT

CSC_FLAGS="-debug -codepage:utf8"

AC_SUBST(LIB_SUFFIX)
AC_SUBST(LIB_PREFIX)
AC_SUBST(ASSEMBLY_VERSION)
AC_SUBST(SQLITE_XML)
AC_SUBST(CSC_FLAGS)


MD_DIR='$(prefix)/lib/monodevelop'
MD_ASSEMBLY_DIR="$MD_DIR/bin"
MD_ADDIN_DIR="$MD_DIR/AddIns"

AC_SUBST(MD_ASSEMBLY_DIR)
AC_SUBST(MD_ADDIN_DIR)
AC_SUBST(MD_DIR)

AC_OUTPUT([
build/data/Makefile
build/data/resources/css/Makefile
build/data/resources/Makefile
build/Makefile
contrib/Makefile
contrib/Mono.Addins/Makefile
contrib/log4net/Makefile
contrib/Mono.Cecil/Makefile
Core/Makefile
Core/src/NRefactory/Makefile
Core/src/Makefile
Core/src/MonoDevelop.Core/AssemblyInfo.cs
Core/src/MonoDevelop.Core/Makefile
Core/src/MonoDevelop.Core/MonoDevelop.Core/GettextCatalog.cs
Core/src/MonoDevelop.Core.Gui/AssemblyInfo.cs
Core/src/MonoDevelop.Core.Gui/Makefile
Core/src/MonoDevelop.Projects/AssemblyInfo.cs
Core/src/MonoDevelop.Projects/MonoDevelop.Projects.dll.config
Core/src/MonoDevelop.Projects/Makefile
Core/src/MonoDevelop.Projects.Gui/AssemblyInfo.cs
Core/src/MonoDevelop.Projects.Gui/Makefile
Core/src/MonoDevelop.Documentation/AssemblyInfo.cs
Core/src/MonoDevelop.Documentation/Makefile
Core/src/MonoDevelop.Ide/AssemblyInfo.cs
Core/src/MonoDevelop.Ide/Makefile
Core/src/MonoDevelop.Dock/Makefile
Core/src/MonoDevelop.Components/AssemblyInfo.cs
Core/src/MonoDevelop.Components/Makefile
Core/src/MonoDevelop.Startup/AssemblyInfo.cs
Core/src/MonoDevelop.Startup/Makefile
Core/src/Tools/Makefile
Core/src/Tools/mdhost/Makefile
Core/src/Tools/mdrun/Makefile
Core/src/Tools/SharpCoco/Makefile
Extras/BooBinding/Makefile
Extras/BooBinding/BooShell/Makefile
Extras/JavaBinding/Makefile
Extras/Makefile
Extras/MonoDeveloperExtensions/Makefile
Extras/MonoDeveloperExtensions/NUnit/Makefile
Extras/MonoQuery/Makefile
Extras/MonoQuery/Mono.Data.Sql/Makefile
Extras/MonoQuery/MonoQuery/Makefile
Extras/NUnit/Makefile
Extras/VersionControl/Diff/Makefile
Extras/VersionControl/DiffWidget/Makefile
Extras/VersionControl/MonoDevelop.VersionControl/Makefile
Extras/VersionControl/MonoDevelop.VersionControl.Subversion/Makefile
Extras/VersionControl/Makefile
Extras/CSharpBinding/Makefile
Extras/CSharpBinding/Autotools/Makefile
Extras/ILAsmBinding/Makefile
Extras/NemerleBinding/Makefile
Extras/VBNetBinding/Makefile
Extras/DebuggerAddIn/AssemblyInfo.cs
Extras/DebuggerAddIn/Makefile
Extras/DebuggerAddIn/DebuggerPaths.cs
Extras/MonoDevelop.SourceEditor/AssemblyInfo.cs
Extras/MonoDevelop.SourceEditor/Makefile
Extras/prj2make-sharp-lib/AssemblyInfo.cs
Extras/prj2make-sharp-lib/Makefile
Extras/WelcomePage/Makefile
Extras/ChangeLogAddIn/Makefile
Extras/MonoDevelop.GtkCore/Makefile
Extras/MonoDevelop.GtkCore/lib/Makefile
Extras/AspNetAddIn/Makefile
Extras/MonoDevelop.Autotools/Makefile
Extras/MonoDevelop.DesignerSupport/Makefile
Extras/AspNetEdit/Makefile
Extras/AspNetEdit/chrome/Makefile
Extras/AspNetEdit/chrome/aspdesigner.manifest
Extras/MonoDevelop.WebReferences/Makefile
Extras/Deployment/Makefile
Extras/Deployment/MonoDevelop.Deployment/Makefile
Extras/Deployment/MonoDevelop.Deployment.Linux/Makefile
Extras/MonoDevelop.Gettext/Makefile
Extras/MonoDevelop.RegexToolkit/Makefile
Extras/CBinding/Makefile
Makefile
monodevelop
mdtool
monodevelop.pc
po/Makefile.in
man/Makefile
])

echo ""
echo "Configuration summary"
echo ""
echo "   * Installation prefix = $prefix"
echo "   * C# compiler = $CSC"
echo "   * Mozilla home: $MOZILLA_HOME"
echo "   * mono-debugger: $enable_debugger"
echo "   * MonoQuery support: $enable_monoquery"

if test "x$enable_monoquery" = "xyes"; then
echo "   *   Providers:"
echo "   *     PostgreSQL:   $enable_postgres"
echo "   *     MySQL:        $enable_mysql"
echo "   *     SQLite:       $enable_sqlite"
echo "   *     Oracle:       $enable_oracle"
echo "   *     SQL Server:   $enable_sqlserv"
echo "   *     Sybase:       $enable_sybase"
fi

echo "   * java support: $enable_java"
echo "   * boo support: $enable_boo"
echo "   * Nemerle support: $enable_nemerle"
echo "   * Mono class library development extensions: $enable_monoextensions"
echo "   * Version control support: $enable_versioncontrol"
echo "   *   Providers:"
echo "   *     Subversion: $enable_subversion"
echo "   * ASP.NET project support: $enable_aspnet"
echo "   * ASP.NET Visual Designer: $enable_aspnetedit"
echo "   * Web References: yes"
echo "   * C/C++ project support: $enable_c"
echo ""