Extract .dSYM debug symbols on Mac OS X when using CONFIG=symbols.

1 files changed, 33 insertions, 0 deletions

diff --git a/symbols.pri b/symbols.pri
new file mode 100644
index 000000000..dfdab2078
--- /dev/null
+++ b/symbols.pri
@@ -0,0 +1,33 @@
+CONFIG(symbols):macx {
+	CONFIG(debug, debug|release) {
+		DSYM_DESTDIR = $${PWD}/debug
+	}
+
+	CONFIG(release, debug|release) {
+		DSYM_DESTDIR = $${PWD}/release
+	}
+
+	contains(TEMPLATE, 'app') {
+		DSYM_TARGET_FULLPATH = ${TARGET}
+		DSYM_OUT = $${DSYM_DESTDIR}/symbols/${QMAKE_TARGET}.dSYM
+		CONFIG(app_bundle) {
+			DSYM_OUT = $${DSYM_DESTDIR}/symbols/${QMAKE_TARGET}.app.dSYM
+		}
+	}
+
+	contains(TEMPLATE, 'lib') {
+		DSYM_TARGET_FULLPATH = $${DESTDIR}/${TARGET}
+		DSYM_OUT = $${DSYM_DESTDIR}/symbols/${TARGET}.dSYM
+	}		
+
+	dsym.target = $${DSYM_OUT}
+	dsym.commands = $(MKDIR) $${DSYM_DESTDIR}/symbols/ && dsymutil $${DSYM_TARGET_FULLPATH} -o $${DSYM_OUT}
+	dsym.depends = $${DSYM_TARGET_FULLPATH}
+	dsym.CONFIG = recursive
+	QMAKE_EXTRA_TARGETS *= dsym
+	QMAKE_DISTCLEAN *= $${DSYM_OUT}
+
+	!CONFIG(staticlib) {
+		ALL_DEPS += $${DSYM_OUT}
+	}
+}