blob: 0be7db2bad0c195d7d457eb59c15b03313f5364b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
include(../../qmake/compiler.pri)
BUILDDIR=$$basename(PWD)
SOURCEDIR=$$replace(BUILDDIR,-build,-src)
VERSION=$$replace(BUILDDIR,-build,)
VERSION=$$replace(VERSION,celt-,)
!exists(../$$SOURCEDIR/COPYING) {
message("The $$SOURCEDIR/ directory was not found. Please update your submodules (git submodule update --init) or build with CONFIG+=no-bundled-celt.")
error("Aborting configuration")
}
TEMPLATE = lib
CONFIG -= qt
CONFIG += debug_and_release
CONFIG += no_include_pwd
VPATH = ../$$SOURCEDIR/libcelt
TARGET = celt0
RC_FILE = celt-0.11.0.rc
DEFINES += HAVE_CONFIG_H
TARGET_VERSION_EXT = .$$VERSION
CONFIG(static) {
CONFIG -= static
CONFIG += shared
}
!CONFIG(third-party-warnings) {
# We ignore warnings in third party builds. We won't actually look
# at them and they clutter out our warnings.
CONFIG -= warn_on
CONFIG += warn_off
}
QMAKE_CFLAGS -= -fPIE -pie
win32 {
DEFINES += WIN32 _WIN32
INCLUDEPATH += ../$$BUILDDIR/win32
CONFIG(sse2) {
TARGET_VERSION_EXT = .$${VERSION}.sse2
} else {
QMAKE_CFLAGS_RELEASE -= -arch:SSE
QMAKE_CFLAGS_DEBUG -= -arch:SSE
}
}
unix {
contains(QMAKE_CFLAGS, -ffast-math) {
DEFINES += FLOAT_APPROX
}
INCLUDEPATH += ../$$BUILDDIR
}
DIST = config.h
SOURCES *= bands.c celt.c cwrs.c entcode.c entdec.c entenc.c header.c kiss_fft.c laplace.c mathops.c mdct.c modes.c pitch.c plc.c quant_bands.c rate.c vq.c
CONFIG(debug, debug|release) {
CONFIG += console
DESTDIR = ../../debug
}
CONFIG(release, debug|release) {
DESTDIR = ../../release
}
include(../../qmake/symbols.pri)
|
