blob: b871774d76700d5e7a26fd8149869c523f276d8f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 2005-2016 The Mumble Developers. All rights reserved.
# Use of this source code is governed by a BSD-style license
# that can be found in the LICENSE file at the root of the
# Mumble source tree or at <https://www.mumble.info/LICENSE>.
# Overlay payload for Unix-like systems and OS X.
include(../compiler.pri)
TEMPLATE = lib
CONFIG -= qt gui
CONFIG *= debug_and_release
VERSION = 1.3.0
SOURCES = overlay.c
CONFIG(static) {
CONFIG -= static
}
unix:!macx {
TARGET = mumble$(TARGET_ADD)
DEFINES += TARGET_UNIX
linux {
LIBS *= -lrt -ldl
}
QMAKE_CFLAGS *= -fvisibility=hidden $(CFLAGS_ADD)
QMAKE_LFLAGS -= -Wl,--no-undefined
QMAKE_LFLAGS -= -Wl,-z,now
QMAKE_LFLAGS += -Wl,-z,lazy
QMAKE_LFLAGS *= $(LFLAGS_ADD)
equals(QMAKE_LINK,g++) {
QMAKE_LINK = gcc
QMAKE_LINK_SHLIB = gcc
}
}
macx {
CONFIG *= x86_64 x86 plugin
CONFIG(universal) {
CONFIG *= ppc
}
TARGET = mumbleoverlay$(TARGET_ADD)
DEFINES += TARGET_MAC
QMAKE_CFLAGS *= -x objective-c
QMAKE_CFLAGS *= $(CFLAGS_ADD)
QMAKE_LFLAGS_PLUGIN *= -undefined dynamic_lookup -dynamic
QMAKE_LFLAGS += -framework CoreFoundation
QMAKE_LFLAGS += $(LFLAGS_ADD)
QMAKE_INFO_PLIST = overlay_gl.plist
INCLUDEPATH *= ../3rdparty/mach-override-src
LIBS *= -lmach-override
}
CONFIG(debug, debug|release) {
QMAKE_LIBDIR *= ../debug$(DESTDIR_ADD)
DESTDIR = ../debug$(DESTDIR_ADD)
}
CONFIG(release, debug|release) {
QMAKE_LIBDIR *= ../release$(DESTDIR_ADD)
DESTDIR = ../release$(DESTDIR_ADD)
}
include(../symbols.pri)
|
