Cycles: add Vector Displacement node and extend Displacement node.

This adds midlevel and object/world space for displacement, and a
vector displacement node with tangent/object/world space, midlevel
and scale.

Note that tangent space vector displacement still is not exactly
compatible with maps created by other software, this will require
changes to the tangent computation.

Differential Revision: https://developer.blender.org/D1734

3 files changed, 73 insertions, 3 deletions

diff --git a/intern/cycles/kernel/shaders/CMakeLists.txt b/intern/cycles/kernel/shaders/CMakeLists.txt
index fb983a44579..5e8e98773d9 100644
--- a/intern/cycles/kernel/shaders/CMakeLists.txt
+++ b/intern/cycles/kernel/shaders/CMakeLists.txt
@@ -24,6 +24,7 @@ set(SRC_OSL
 	node_convert_from_vector.osl
 	node_diffuse_bsdf.osl
 	node_displacement.osl
+	node_vector_displacement.osl
 	node_emission.osl
 	node_environment_texture.osl
 	node_fresnel.osl
diff --git a/intern/cycles/kernel/shaders/node_displacement.osl b/intern/cycles/kernel/shaders/node_displacement.osl
index fb81533c778..89f35841527 100644
--- a/intern/cycles/kernel/shaders/node_displacement.osl
+++ b/intern/cycles/kernel/shaders/node_displacement.osl
@@ -17,13 +17,22 @@
 #include "stdosl.h"
 
 shader node_displacement(
+	string space = "object",
 	float Height = 0.0,
+	float Midlevel = 0.5,
 	float Scale = 1.0,
 	normal Normal = N,
 	output vector Displacement = vector(0.0, 0.0, 0.0))
 {
-	Displacement = normalize(transform("object", Normal));
-	Displacement *= Height * Scale;
-	Displacement = transform("object", "world", Displacement);
+	Displacement = Normal;
+	if(space == "object") {
+		Displacement = transform("object", Displacement);
+	}
+
+	Displacement = normalize(Displacement) * (Height - Midlevel) * Scale;
+
+	if(space == "object") {
+		Displacement = transform("object", "world", Displacement);
+	}
 }
 
diff --git a/intern/cycles/kernel/shaders/node_vector_displacement.osl b/intern/cycles/kernel/shaders/node_vector_displacement.osl
new file mode 100644
index 00000000000..b19bc228e37
--- /dev/null
+++ b/intern/cycles/kernel/shaders/node_vector_displacement.osl
@@ -0,0 +1,60 @@
+/*
+ * Copyright 2011-2013 Blender Foundation
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+#include "stdosl.h"
+
+shader node_vector_displacement(
+	color Vector = color(0.0, 0.0, 0.0),
+	float Midlevel = 0.0,
+	float Scale = 1.0,
+	string space = "tangent",
+	string attr_name = "geom:tangent",
+	string attr_sign_name = "geom:tangent_sign",
+	output vector Displacement = vector(0.0, 0.0, 0.0))
+{
+	vector offset = (Vector - vector(Midlevel)) * Scale;
+
+	if(space == "tangent") {
+		/* Tangent space. */
+		vector N_object = normalize(transform("world", "object", N));
+
+		vector T_object;
+		if(getattribute(attr_name, T_object)) {
+			T_object = normalize(T_object);
+		}
+		else {
+			T_object = normalize(dPdu);
+		}
+
+		vector B_object = normalize(cross(N_object, T_object));
+		float tangent_sign;
+		if(getattribute(attr_sign_name, tangent_sign)) {
+			B_object *= tangent_sign;
+		}
+
+		Displacement = T_object*offset[0] + N_object*offset[1] + B_object*offset[2];
+	}
+	else {
+		/* Object or world space. */
+		Displacement = offset;
+	}
+
+	if(space != "world") {
+		/* Tangent or object space. */
+		Displacement = transform("object", "world", Displacement);
+	}
+}
+