GPU: Split gpu_shader_material into multiple files.

This patch continue the efforts to split the `gpu_shader_material` file
started in D5569.

Dependency resolution is now recursive. Each shading node gets its own
file. Additionally, some utility files are added to be shared between
files, like `math_util`, `color_util`, and `hash`. Some files are always
included because they may be used in the execution function, like
`world_normals`.

Some glsl functions appeared to be unused, so they were removed, like
`output_node`, `bits_to_01`, and `exp_blender`. Other functions have
been renamed to be more general and get used as utils, like `texco_norm`
which became `vector_normalize`.

A lot of the opengl tests fails, but those same tests also fail in
master, so this is probably unrelated to this patch.

Reviewers: brecht

Differential Revision: https://developer.blender.org/D5616

1 files changed, 44 insertions, 0 deletions

diff --git a/source/blender/gpu/shaders/material/gpu_shader_material_tex_environment.glsl b/source/blender/gpu/shaders/material/gpu_shader_material_tex_environment.glsl
new file mode 100644
index 00000000000..9bd36f8a757
--- /dev/null
+++ b/source/blender/gpu/shaders/material/gpu_shader_material_tex_environment.glsl
@@ -0,0 +1,44 @@
+void node_tex_environment_texco(vec3 viewvec, out vec3 worldvec)
+{
+#ifdef MESH_SHADER
+  worldvec = worldPosition;
+#else
+  vec4 v = (ProjectionMatrix[3][3] == 0.0) ? vec4(viewvec, 1.0) : vec4(0.0, 0.0, 1.0, 1.0);
+  vec4 co_homogenous = (ProjectionMatrixInverse * v);
+
+  vec3 co = co_homogenous.xyz / co_homogenous.w;
+#  if defined(WORLD_BACKGROUND) || defined(PROBE_CAPTURE)
+  worldvec = mat3(ViewMatrixInverse) * co;
+#  else
+  worldvec = mat3(ModelMatrixInverse) * (mat3(ViewMatrixInverse) * co);
+#  endif
+#endif
+}
+
+void node_tex_environment_equirectangular(vec3 co, float clamp_size, sampler2D ima, out vec3 uv)
+{
+  vec3 nco = normalize(co);
+  uv.x = -atan(nco.y, nco.x) / (2.0 * M_PI) + 0.5;
+  uv.y = atan(nco.z, hypot(nco.x, nco.y)) / M_PI + 0.5;
+
+  /* Fix pole bleeding */
+  float half_height = clamp_size / float(textureSize(ima, 0).y);
+  uv.y = clamp(uv.y, half_height, 1.0 - half_height);
+  uv.z = 0.0;
+}
+
+void node_tex_environment_mirror_ball(vec3 co, out vec3 uv)
+{
+  vec3 nco = normalize(co);
+  nco.y -= 1.0;
+
+  float div = 2.0 * sqrt(max(-0.5 * nco.y, 0.0));
+  nco /= max(1e-8, div);
+
+  uv = 0.5 * nco.xzz + 0.5;
+}
+
+void node_tex_environment_empty(vec3 co, out vec4 color)
+{
+  color = vec4(1.0, 0.0, 1.0, 1.0);
+}