Realtime Compositor: Add basic color nodes

This patch implements the following nodes for the realtime compositor:

- Alpha over node.
- Bright contrast node.
- Color balance node.
- Color correction node.
- Exposure node.
- Gamma node.
- Hue correct node.
- Hue saturation value node.
- Invert node.
- Mix node.
- Posterize node.
- Time curve node.
- Vector curve node.

Differential Revision: https://developer.blender.org/D15228

Reviewed By: Clement Foucault

14 files changed, 453 insertions, 23 deletions

diff --git a/source/blender/gpu/shaders/common/gpu_shader_common_color_utils.glsl b/source/blender/gpu/shaders/common/gpu_shader_common_color_utils.glsl
index fe89985ae7f..2ac0ff8c4bb 100644
--- a/source/blender/gpu/shaders/common/gpu_shader_common_color_utils.glsl
+++ b/source/blender/gpu/shaders/common/gpu_shader_common_color_utils.glsl
@@ -140,6 +140,8 @@ void hsl_to_rgb(vec4 hsl, out vec4 outcol)
   outcol = vec4((nr - 0.5) * chroma + l, (ng - 0.5) * chroma + l, (nb - 0.5) * chroma + l, hsl.w);
 }
 
+/* ** Alpha Handling ** */
+
 void color_alpha_clear(vec4 color, out vec4 result)
 {
   result = vec4(color.rgb, 1.0);
@@ -147,15 +149,50 @@ void color_alpha_clear(vec4 color, out vec4 result)
 
 void color_alpha_premultiply(vec4 color, out vec4 result)
 {
-  result = vec4(color.rgb * color.a, 1.0);
+  result = vec4(color.rgb * color.a, color.a);
 }
 
 void color_alpha_unpremultiply(vec4 color, out vec4 result)
 {
   if (color.a == 0.0 || color.a == 1.0) {
-    result = vec4(color.rgb, 1.0);
+    result = color;
   }
   else {
-    result = vec4(color.rgb / color.a, 1.0);
+    result = vec4(color.rgb / color.a, color.a);
+  }
+}
+
+float linear_rgb_to_srgb(float color)
+{
+  if (color < 0.0031308) {
+    return (color < 0.0) ? 0.0 : color * 12.92;
+  }
+
+  return 1.055 * pow(color, 1.0 / 2.4) - 0.055;
+}
+
+vec3 linear_rgb_to_srgb(vec3 color)
+{
+  return vec3(
+      linear_rgb_to_srgb(color.r), linear_rgb_to_srgb(color.g), linear_rgb_to_srgb(color.b));
+}
+
+float srgb_to_linear_rgb(float color)
+{
+  if (color < 0.04045) {
+    return (color < 0.0) ? 0.0 : color * (1.0 / 12.92);
   }
+
+  return pow((color + 0.055) * (1.0 / 1.055), 2.4);
+}
+
+vec3 srgb_to_linear_rgb(vec3 color)
+{
+  return vec3(
+      srgb_to_linear_rgb(color.r), srgb_to_linear_rgb(color.g), srgb_to_linear_rgb(color.b));
+}
+
+float get_luminance(vec3 color, vec3 luminance_coefficients)
+{
+  return dot(color, luminance_coefficients);
 }
diff --git a/source/blender/gpu/shaders/common/gpu_shader_common_curves.glsl b/source/blender/gpu/shaders/common/gpu_shader_common_curves.glsl
index 8948ed77557..db8e114ec7a 100644
--- a/source/blender/gpu/shaders/common/gpu_shader_common_curves.glsl
+++ b/source/blender/gpu/shaders/common/gpu_shader_common_curves.glsl
@@ -95,6 +95,81 @@ void curves_combined_only(float factor,
   result = mix(color, result, factor);
 }
 
+/* Contrary to standard tone curve implementations, the film-like implementation tries to preserve
+ * the hue of the colors as much as possible. To understand why this might be a problem, consider
+ * the violet color (0.5, 0.0, 1.0). If this color was to be evaluated at a power curve x^4, the
+ * color will be blue (0.0625, 0.0, 1.0). So the color changes and not just its luminosity, which
+ * is what film-like tone curves tries to avoid.
+ *
+ * First, the channels with the lowest and highest values are identified and evaluated at the
+ * curve. Then, the third channel---the median---is computed while maintaining the original hue of
+ * the color. To do that, we look at the equation for deriving the hue from RGB values. Assuming
+ * the maximum, minimum, and median channels are known, and ignoring the 1/3 period offset of the
+ * hue, the equation is:
+ *
+ *   hue = (median - min) / (max - min)                                  [1]
+ *
+ * Since we have the new values for the minimum and maximum after evaluating at the curve, we also
+ * have:
+ *
+ *   hue = (new_median - new_min) / (new_max - new_min)                  [2]
+ *
+ * Since we want the hue to be equivalent, by equating [1] and [2] and rearranging:
+ *
+ *   (new_median - new_min) / (new_max - new_min) = (median - min) / (max - min)
+ *   new_median - new_min = (new_max - new_min) * (median - min) / (max - min)
+ *   new_median = new_min + (new_max - new_min) * (median - min) / (max - min)
+ *   new_median = new_min + (median - min) * ((new_max - new_min) / (max - min))  [QED]
+ *
+ * Which gives us the median color that preserves the hue. More intuitively, the median is computed
+ * such that the change in the distance from the median to the minimum is proportional to the
+ * change in the distance from the minimum to the maximum. Finally, each of the new minimum,
+ * maximum, and median values are written to the color channel that they were originally extracted
+ * from. */
+void curves_film_like(float factor,
+                      vec4 color,
+                      vec4 black_level,
+                      vec4 white_level,
+                      sampler1DArray curve_map,
+                      const float layer,
+                      float range_minimum,
+                      float range_divider,
+                      float start_slope,
+                      float end_slope,
+                      out vec4 result)
+{
+  vec4 balanced = white_balance(color, black_level, white_level);
+
+  /* Find the maximum, minimum, and median of the color channels. */
+  float minimum = min(balanced.r, min(balanced.g, balanced.b));
+  float maximum = max(balanced.r, max(balanced.g, balanced.b));
+  float median = max(min(balanced.r, balanced.g), min(balanced.b, max(balanced.r, balanced.g)));
+
+  /* Evaluate alpha curve map at the maximum and minimum channels. The alpha curve is the Combined
+   * curve in the UI. */
+  float min_parameter = NORMALIZE_PARAMETER(minimum, range_minimum, range_divider);
+  float max_parameter = NORMALIZE_PARAMETER(maximum, range_minimum, range_divider);
+  float new_min = texture(curve_map, vec2(min_parameter, layer)).a;
+  float new_max = texture(curve_map, vec2(max_parameter, layer)).a;
+
+  /* Then, extrapolate if needed. */
+  new_min = extrapolate_if_needed(min_parameter, new_min, start_slope, end_slope);
+  new_max = extrapolate_if_needed(max_parameter, new_max, start_slope, end_slope);
+
+  /* Compute the new median using the ratio between the new and the original range. */
+  float scaling_ratio = (new_max - new_min) / (maximum - minimum);
+  float new_median = new_min + (median - minimum) * scaling_ratio;
+
+  /* Write each value to its original channel. */
+  bvec3 channel_is_min = equal(balanced.rgb, vec3(minimum));
+  vec3 median_or_min = mix(vec3(new_median), vec3(new_min), channel_is_min);
+  bvec3 channel_is_max = equal(balanced.rgb, vec3(maximum));
+  result.rgb = mix(median_or_min, vec3(new_max), channel_is_max);
+  result.a = color.a;
+
+  result = mix(color, result, clamp(factor, 0.0, 1.0));
+}
+
 void curves_vector(vec3 vector,
                    sampler1DArray curve_map,
                    const float layer,
diff --git a/source/blender/gpu/shaders/common/gpu_shader_common_math_utils.glsl b/source/blender/gpu/shaders/common/gpu_shader_common_math_utils.glsl
index 124654963fd..a28705f158d 100644
--- a/source/blender/gpu/shaders/common/gpu_shader_common_math_utils.glsl
+++ b/source/blender/gpu/shaders/common/gpu_shader_common_math_utils.glsl
@@ -34,6 +34,17 @@ float compatible_pow(float x, float y)
   return pow(x, y);
 }
 
+/* A version of pow that returns a fallback value if the computation is undefined. From the spec:
+ * The result is undefined if x < 0 or if x = 0 and y is less than or equal 0. */
+float fallback_pow(float x, float y, float fallback)
+{
+  if (x < 0.0 || (x == 0.0 && y <= 0.0)) {
+    return fallback;
+  }
+
+  return pow(x, y);
+}
+
 float wrap(float a, float b, float c)
 {
   float range = b - c;
@@ -114,6 +125,13 @@ void vector_copy(vec3 normal, out vec3 outnormal)
   outnormal = normal;
 }
 
+vec3 fallback_pow(vec3 a, float b, vec3 fallback)
+{
+  return vec3(fallback_pow(a.x, b, fallback.x),
+              fallback_pow(a.y, b, fallback.y),
+              fallback_pow(a.z, b, fallback.z));
+}
+
 /* Matirx Math */
 
 mat3 euler_to_mat3(vec3 euler)
diff --git a/source/blender/gpu/shaders/common/gpu_shader_common_mix_rgb.glsl b/source/blender/gpu/shaders/common/gpu_shader_common_mix_rgb.glsl
index f9652f1150b..39f3c722dd2 100644
--- a/source/blender/gpu/shaders/common/gpu_shader_common_mix_rgb.glsl
+++ b/source/blender/gpu/shaders/common/gpu_shader_common_mix_rgb.glsl
@@ -2,28 +2,24 @@
 
 void mix_blend(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   outcol = mix(col1, col2, fac);
   outcol.a = col1.a;
 }
 
 void mix_add(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   outcol = mix(col1, col1 + col2, fac);
   outcol.a = col1.a;
 }
 
 void mix_mult(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   outcol = mix(col1, col1 * col2, fac);
   outcol.a = col1.a;
 }
 
 void mix_screen(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   float facm = 1.0 - fac;
 
   outcol = vec4(1.0) - (vec4(facm) + fac * (vec4(1.0) - col2)) * (vec4(1.0) - col1);
@@ -32,7 +28,6 @@ void mix_screen(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 
 void mix_overlay(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   float facm = 1.0 - fac;
 
   outcol = col1;
@@ -61,14 +56,30 @@ void mix_overlay(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 
 void mix_sub(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   outcol = mix(col1, col1 - col2, fac);
   outcol.a = col1.a;
 }
 
 void mix_div(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
+  float facm = 1.0 - fac;
+
+  outcol = vec4(vec3(0.0), col1.a);
+
+  if (col2.r != 0.0) {
+    outcol.r = facm * col1.r + fac * col1.r / col2.r;
+  }
+  if (col2.g != 0.0) {
+    outcol.g = facm * col1.g + fac * col1.g / col2.g;
+  }
+  if (col2.b != 0.0) {
+    outcol.b = facm * col1.b + fac * col1.b / col2.b;
+  }
+}
+
+/* A variant of mix_div that fallback to the first color upon zero division. */
+void mix_div_fallback(float fac, vec4 col1, vec4 col2, out vec4 outcol)
+{
   float facm = 1.0 - fac;
 
   outcol = col1;
@@ -86,28 +97,24 @@ void mix_div(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 
 void mix_diff(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   outcol = mix(col1, abs(col1 - col2), fac);
   outcol.a = col1.a;
 }
 
 void mix_dark(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   outcol.rgb = mix(col1.rgb, min(col1.rgb, col2.rgb), fac);
   outcol.a = col1.a;
 }
 
 void mix_light(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   outcol.rgb = mix(col1.rgb, max(col1.rgb, col2.rgb), fac);
   outcol.a = col1.a;
 }
 
 void mix_dodge(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   outcol = col1;
 
   if (outcol.r != 0.0) {
@@ -150,7 +157,6 @@ void mix_dodge(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 
 void mix_burn(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   float tmp, facm = 1.0 - fac;
 
   outcol = col1;
@@ -200,7 +206,6 @@ void mix_burn(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 
 void mix_hue(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   float facm = 1.0 - fac;
 
   outcol = col1;
@@ -220,7 +225,6 @@ void mix_hue(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 
 void mix_sat(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   float facm = 1.0 - fac;
 
   outcol = col1;
@@ -238,7 +242,6 @@ void mix_sat(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 
 void mix_val(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   float facm = 1.0 - fac;
 
   vec4 hsv, hsv2;
@@ -251,7 +254,6 @@ void mix_val(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 
 void mix_color(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   float facm = 1.0 - fac;
 
   outcol = col1;
@@ -272,22 +274,26 @@ void mix_color(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 
 void mix_soft(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
   float facm = 1.0 - fac;
 
   vec4 one = vec4(1.0);
   vec4 scr = one - (one - col2) * (one - col1);
   outcol = facm * col1 + fac * ((one - col1) * col2 * col1 + col1 * scr);
+  outcol.a = col1.a;
 }
 
 void mix_linear(float fac, vec4 col1, vec4 col2, out vec4 outcol)
 {
-  fac = clamp(fac, 0.0, 1.0);
-
   outcol = col1 + fac * (2.0 * (col2 - vec4(0.5)));
+  outcol.a = col1.a;
 }
 
-void clamp_color(vec3 vec, vec3 min, vec3 max, out vec3 out_vec)
+void clamp_color(vec4 vec, const vec4 min, const vec4 max, out vec4 out_vec)
 {
   out_vec = clamp(vec, min, max);
 }
+
+void multiply_by_alpha(float factor, vec4 color, out float result)
+{
+  result = factor * color.a;
+}
diff --git a/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_alpha_over.glsl b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_alpha_over.glsl
new file mode 100644
index 00000000000..8e3e033147f
--- /dev/null
+++ b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_alpha_over.glsl
@@ -0,0 +1,48 @@
+void node_composite_alpha_over_mixed(
+    float factor, vec4 color, vec4 over_color, float premultiply_factor, out vec4 result)
+{
+  if (over_color.a <= 0.0) {
+    result = color;
+  }
+  else if (factor == 1.0 && over_color.a >= 1.0) {
+    result = over_color;
+  }
+  else {
+    float add_factor = 1.0 - premultiply_factor + over_color.a * premultiply_factor;
+    float premultiplier = factor * add_factor;
+    float multiplier = 1.0 - factor * over_color.a;
+
+    result = multiplier * color + vec2(premultiplier, factor).xxxy * over_color;
+  }
+}
+
+void node_composite_alpha_over_key(float factor, vec4 color, vec4 over_color, out vec4 result)
+{
+  if (over_color.a <= 0.0) {
+    result = color;
+  }
+  else if (factor == 1.0 && over_color.a >= 1.0) {
+    result = over_color;
+  }
+  else {
+    result = mix(color, vec4(over_color.rgb, 1.0), factor * over_color.a);
+  }
+}
+
+void node_composite_alpha_over_premultiply(float factor,
+                                           vec4 color,
+                                           vec4 over_color,
+                                           out vec4 result)
+{
+  if (over_color.a < 0.0) {
+    result = color;
+  }
+  else if (factor == 1.0 && over_color.a >= 1.0) {
+    result = over_color;
+  }
+  else {
+    float multiplier = 1.0 - factor * over_color.a;
+
+    result = multiplier * color + factor * over_color;
+  }
+}
diff --git a/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_bright_contrast.glsl b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_bright_contrast.glsl
new file mode 100644
index 00000000000..ce71b4fd8a4
--- /dev/null
+++ b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_bright_contrast.glsl
@@ -0,0 +1,38 @@
+#pragma BLENDER_REQUIRE(gpu_shader_common_color_utils.glsl)
+
+/* The algorithm is by Werner D. Streidt
+ * (http://visca.com/ffactory/archives/5-99/msg00021.html)
+ * Extracted of OpenCV demhist.c
+ */
+
+#define FLT_EPSILON 1.192092896e-07F
+
+void node_composite_bright_contrast(
+    vec4 color, float brightness, float contrast, const float use_premultiply, out vec4 result)
+{
+  brightness /= 100.0;
+  float delta = contrast / 200.0;
+
+  float multiplier, offset;
+  if (contrast > 0.0) {
+    multiplier = 1.0 - delta * 2.0;
+    multiplier = 1.0 / max(multiplier, FLT_EPSILON);
+    offset = multiplier * (brightness - delta);
+  }
+  else {
+    delta *= -1.0;
+    multiplier = max(1.0 - delta * 2.0, 0.0);
+    offset = multiplier * brightness + delta;
+  }
+
+  if (use_premultiply != 0.0) {
+    color_alpha_unpremultiply(color, color);
+  }
+
+  result.rgb = color.rgb * multiplier + offset;
+  result.a = color.a;
+
+  if (use_premultiply != 0.0) {
+    color_alpha_premultiply(result, result);
+  }
+}
diff --git a/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_color_balance.glsl b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_color_balance.glsl
new file mode 100644
index 00000000000..bffb94cdedb
--- /dev/null
+++ b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_color_balance.glsl
@@ -0,0 +1,34 @@
+#pragma BLENDER_REQUIRE(gpu_shader_common_color_utils.glsl)
+
+void node_composite_color_balance_lgg(
+    float factor, vec4 color, vec3 lift, vec3 gamma, vec3 gain, out vec4 result)
+{
+  lift = 2.0 - lift;
+  vec3 srgb_color = linear_rgb_to_srgb(color.rgb);
+  vec3 lift_balanced = ((srgb_color - 1.0) * lift) + 1.0;
+
+  vec3 gain_balanced = lift_balanced * gain;
+  gain_balanced = max(gain_balanced, vec3(0.0));
+
+  vec3 linear_color = srgb_to_linear_rgb(gain_balanced);
+  gamma = mix(gamma, vec3(1e-6), equal(gamma, vec3(0.0)));
+  vec3 gamma_balanced = pow(linear_color, 1.0 / gamma);
+
+  result.rgb = mix(color.rgb, gamma_balanced, min(factor, 1.0));
+  result.a = color.a;
+}
+
+void node_composite_color_balance_asc_cdl(float factor,
+                                          vec4 color,
+                                          vec3 offset,
+                                          vec3 power,
+                                          vec3 slope,
+                                          float offset_basis,
+                                          out vec4 result)
+{
+  offset += offset_basis;
+  vec3 balanced = color.rgb * slope + offset;
+  balanced = pow(max(balanced, vec3(0.0)), power);
+  result.rgb = mix(color.rgb, balanced, min(factor, 1.0));
+  result.a = color.a;
+}
diff --git a/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_color_correction.glsl b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_color_correction.glsl
new file mode 100644
index 00000000000..9b4858f03be
--- /dev/null
+++ b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_color_correction.glsl
@@ -0,0 +1,87 @@
+#pragma BLENDER_REQUIRE(gpu_shader_common_math_utils.glsl)
+#pragma BLENDER_REQUIRE(gpu_shader_common_color_utils.glsl)
+
+void node_composite_color_correction(vec4 color,
+                                     float mask,
+                                     const vec3 enabled_channels,
+                                     float start_midtones,
+                                     float end_midtones,
+                                     float master_saturation,
+                                     float master_contrast,
+                                     float master_gamma,
+                                     float master_gain,
+                                     float master_lift,
+                                     float shadows_saturation,
+                                     float shadows_contrast,
+                                     float shadows_gamma,
+                                     float shadows_gain,
+                                     float shadows_lift,
+                                     float midtones_saturation,
+                                     float midtones_contrast,
+                                     float midtones_gamma,
+                                     float midtones_gain,
+                                     float midtones_lift,
+                                     float highlights_saturation,
+                                     float highlights_contrast,
+                                     float highlights_gamma,
+                                     float highlights_gain,
+                                     float highlights_lift,
+                                     const vec3 luminance_coefficients,
+                                     out vec4 result)
+{
+  const float margin = 0.10;
+  const float margin_divider = 0.5 / margin;
+  float level = (color.r + color.g + color.b) / 3.0;
+  float level_shadows = 0.0;
+  float level_midtones = 0.0;
+  float level_highlights = 0.0;
+  if (level < (start_midtones - margin)) {
+    level_shadows = 1.0;
+  }
+  else if (level < (start_midtones + margin)) {
+    level_midtones = ((level - start_midtones) * margin_divider) + 0.5;
+    level_shadows = 1.0 - level_midtones;
+  }
+  else if (level < (end_midtones - margin)) {
+    level_midtones = 1.0;
+  }
+  else if (level < (end_midtones + margin)) {
+    level_highlights = ((level - end_midtones) * margin_divider) + 0.5;
+    level_midtones = 1.0 - level_highlights;
+  }
+  else {
+    level_highlights = 1.0;
+  }
+
+  float contrast = level_shadows * shadows_contrast;
+  contrast += level_midtones * midtones_contrast;
+  contrast += level_highlights * highlights_contrast;
+  contrast *= master_contrast;
+  float saturation = level_shadows * shadows_saturation;
+  saturation += level_midtones * midtones_saturation;
+  saturation += level_highlights * highlights_saturation;
+  saturation *= master_saturation;
+  float gamma = level_shadows * shadows_gamma;
+  gamma += level_midtones * midtones_gamma;
+  gamma += level_highlights * highlights_gamma;
+  gamma *= master_gamma;
+  float gain = level_shadows * shadows_gain;
+  gain += level_midtones * midtones_gain;
+  gain += level_highlights * highlights_gain;
+  gain *= master_gain;
+  float lift = level_shadows * shadows_lift;
+  lift += level_midtones * midtones_lift;
+  lift += level_highlights * highlights_lift;
+  lift += master_lift;
+
+  float inverse_gamma = 1.0 / gamma;
+  float luma = get_luminance(color.rgb, luminance_coefficients);
+
+  vec3 corrected = luma + saturation * (color.rgb - luma);
+  corrected = 0.5 + (corrected - 0.5) * contrast;
+  corrected = fallback_pow(corrected * gain + lift, inverse_gamma, corrected);
+  corrected = mix(color.rgb, corrected, min(mask, 1.0));
+
+  result.rgb = mix(corrected, color.rgb, equal(enabled_channels, vec3(0.0)));
+  result.a = color.a;
+}
diff --git a/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_exposure.glsl b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_exposure.glsl
new file mode 100644
index 00000000000..f246635a91e
--- /dev/null
+++ b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_exposure.glsl
@@ -0,0 +1,6 @@
+void node_composite_exposure(vec4 color, float exposure, out vec4 result)
+{
+  float multiplier = exp2(exposure);
+  result.rgb = color.rgb * multiplier;
+  result.a = color.a;
+}
diff --git a/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_gamma.glsl b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_gamma.glsl
new file mode 100644
index 00000000000..53070d4b0e2
--- /dev/null
+++ b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_gamma.glsl
@@ -0,0 +1,7 @@
+#pragma BLENDER_REQUIRE(gpu_shader_common_math_utils.glsl)
+
+void node_composite_gamma(vec4 color, float gamma, out vec4 result)
+{
+  result.rgb = fallback_pow(color.rgb, gamma, color.rgb);
+  result.a = color.a;
+}
diff --git a/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_hue_correct.glsl b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_hue_correct.glsl
new file mode 100644
index 00000000000..99eb125cdf2
--- /dev/null
+++ b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_hue_correct.glsl
@@ -0,0 +1,39 @@
+#pragma BLENDER_REQUIRE(gpu_shader_common_color_utils.glsl)
+
+/* Curve maps are stored in sampler objects that are evaluated in the [0, 1] range, so normalize
+ * parameters accordingly. */
+#define NORMALIZE_PARAMETER(parameter, minimum, range) ((parameter - minimum) * range)
+
+void node_composite_hue_correct(float factor,
+                                vec4 color,
+                                sampler1DArray curve_map,
+                                const float layer,
+                                vec3 minimums,
+                                vec3 range_dividers,
+                                out vec4 result)
+{
+  vec4 hsv;
+  rgb_to_hsv(color, hsv);
+
+  /* First, adjust the hue channel on its own, since corrections in the saturation and value
+   * channels depends on the new value of the hue, not its original value. A curve map value of 0.5
+   * means no change in hue, so adjust the value to get an identity at 0.5. Since the identity of
+   * addition is 0, we subtract 0.5 (0.5 - 0.5 = 0). */
+  const float hue_parameter = NORMALIZE_PARAMETER(hsv.x, minimums.x, range_dividers.x);
+  hsv.x += texture(curve_map, vec2(hue_parameter, layer)).x - 0.5;
+
+  /* Second, adjust the saturation and value based on the new value of the hue. A curve map value
+   * of 0.5 means no change in hue, so adjust the value to get an identity at 0.5. Since the
+   * identity of duplication is 1, we multiply by 2 (0.5 * 2 = 1). */
+  vec2 parameters = NORMALIZE_PARAMETER(hsv.x, minimums.yz, range_dividers.yz);
+  hsv.y *= texture(curve_map, vec2(parameters.x, layer)).y * 2.0;
+  hsv.z *= texture(curve_map, vec2(parameters.y, layer)).z * 2.0;
+
+  /* Sanitize the new hue and saturation values. */
+  hsv.x = fract(hsv.x);
+  hsv.y = clamp(hsv.y, 0.0, 1.0);
+
+  hsv_to_rgb(hsv, result);
+
+  result = mix(color, result, factor);
+}
diff --git a/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_hue_saturation_value.glsl b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_hue_saturation_value.glsl
new file mode 100644
index 00000000000..dd5eb33d318
--- /dev/null
+++ b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_hue_saturation_value.glsl
@@ -0,0 +1,16 @@
+#pragma BLENDER_REQUIRE(gpu_shader_common_color_utils.glsl)
+
+void node_composite_hue_saturation_value(
+    vec4 color, float hue, float saturation, float value, float factor, out vec4 result)
+{
+  vec4 hsv;
+  rgb_to_hsv(color, hsv);
+
+  hsv.x = fract(hsv.x + hue + 0.5);
+  hsv.y = clamp(hsv.y * saturation, 0.0, 1.0);
+  hsv.z = hsv.z * value;
+
+  hsv_to_rgb(hsv, result);
+
+  result = mix(color, result, factor);
+}
diff --git a/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_invert.glsl b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_invert.glsl
new file mode 100644
index 00000000000..59be746da7f
--- /dev/null
+++ b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_invert.glsl
@@ -0,0 +1,13 @@
+#pragma BLENDER_REQUIRE(gpu_shader_common_color_utils.glsl)
+
+void node_composite_invert(float fac, vec4 color, float do_rgb, float do_alpha, out vec4 result)
+{
+  result = color;
+  if (do_rgb != 0.0) {
+    result.rgb = 1.0 - result.rgb;
+  }
+  if (do_alpha != 0.0) {
+    result.a = 1.0 - result.a;
+  }
+  result = mix(color, result, fac);
+}
diff --git a/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_posterize.glsl b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_posterize.glsl
new file mode 100644
index 00000000000..ee8ae234abe
--- /dev/null
+++ b/source/blender/gpu/shaders/compositor/library/gpu_shader_compositor_posterize.glsl
@@ -0,0 +1,6 @@
+void node_composite_posterize(vec4 color, float steps, out vec4 result)
+{
+  steps = clamp(steps, 2.0, 1024.0);
+  result = floor(color * steps) / steps;
+  result.a = color.a;
+}