1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
|
/*
* Copyright 2011-2013 Blender Foundation
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
#include "stdosl.h"
#include "node_color.h"
point texco_remap_square(point co)
{
return (co - point(0.5, 0.5, 0.5)) * 2.0;
}
point map_to_tube(vector dir)
{
float u, v;
v = (dir[2] + 1.0) * 0.5;
float len = sqrt(dir[0] * dir[0] + dir[1] * dir[1]);
if (len > 0.0) {
u = (1.0 - (atan2(dir[0] / len, dir[1] / len) / M_PI)) * 0.5;
}
else {
v = u = 0.0; /* To avoid un-initialized variables. */
}
return point(u, v, 0.0);
}
point map_to_sphere(vector dir)
{
float len = length(dir);
float v, u;
if (len > 0.0) {
if (dir[0] == 0.0 && dir[1] == 0.0) {
u = 0.0; /* Othwise domain error. */
}
else {
u = (1.0 - atan2(dir[0], dir[1]) / M_PI) / 2.0;
}
v = 1.0 - acos(dir[2] / len) / M_PI;
}
else {
v = u = 0.0; /* To avoid un-initialized variables. */
}
return point(u, v, 0.0);
}
color image_texture_lookup(string filename,
float u,
float v,
output float Alpha,
int compress_as_srgb,
int ignore_alpha,
int unassociate_alpha,
int is_float,
string interpolation,
string extension)
{
color rgb = (color)texture(
filename, u, 1.0 - v, "wrap", extension, "interp", interpolation, "alpha", Alpha);
if (ignore_alpha) {
Alpha = 1.0;
}
else if (unassociate_alpha) {
rgb = color_unpremultiply(rgb, Alpha);
if (!is_float)
rgb = min(rgb, 1.0);
}
if (compress_as_srgb) {
rgb = color_srgb_to_scene_linear(rgb);
}
return rgb;
}
shader node_image_texture(int use_mapping = 0,
matrix mapping = matrix(0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0),
point Vector = P,
string filename = "",
string projection = "flat",
string interpolation = "smartcubic",
string extension = "periodic",
float projection_blend = 0.0,
int compress_as_srgb = 0,
int ignore_alpha = 0,
int unassociate_alpha = 0,
int is_float = 1,
output color Color = 0.0,
output float Alpha = 1.0)
{
point p = Vector;
if (use_mapping)
p = transform(mapping, p);
if (projection == "flat") {
Color = image_texture_lookup(filename,
p[0],
p[1],
Alpha,
compress_as_srgb,
ignore_alpha,
unassociate_alpha,
is_float,
interpolation,
extension);
}
else if (projection == "box") {
/* object space normal */
vector Nob = transform("world", "object", N);
/* project from direction vector to barycentric coordinates in triangles */
Nob = vector(fabs(Nob[0]), fabs(Nob[1]), fabs(Nob[2]));
Nob /= (Nob[0] + Nob[1] + Nob[2]);
/* basic idea is to think of this as a triangle, each corner representing
* one of the 3 faces of the cube. in the corners we have single textures,
* in between we blend between two textures, and in the middle we a blend
* between three textures.
*
* the Nxyz values are the barycentric coordinates in an equilateral
* triangle, which in case of blending, in the middle has a smaller
* equilateral triangle where 3 textures blend. this divides things into
* 7 zones, with an if () test for each zone */
vector weight = vector(0.0, 0.0, 0.0);
float blend = projection_blend;
float limit = 0.5 * (1.0 + blend);
/* first test for corners with single texture */
if (Nob[0] > limit * (Nob[0] + Nob[1]) && Nob[0] > limit * (Nob[0] + Nob[2])) {
weight[0] = 1.0;
}
else if (Nob[1] > limit * (Nob[0] + Nob[1]) && Nob[1] > limit * (Nob[1] + Nob[2])) {
weight[1] = 1.0;
}
else if (Nob[2] > limit * (Nob[0] + Nob[2]) && Nob[2] > limit * (Nob[1] + Nob[2])) {
weight[2] = 1.0;
}
else if (blend > 0.0) {
/* in case of blending, test for mixes between two textures */
if (Nob[2] < (1.0 - limit) * (Nob[1] + Nob[0])) {
weight[0] = Nob[0] / (Nob[0] + Nob[1]);
weight[0] = clamp((weight[0] - 0.5 * (1.0 - blend)) / blend, 0.0, 1.0);
weight[1] = 1.0 - weight[0];
}
else if (Nob[0] < (1.0 - limit) * (Nob[1] + Nob[2])) {
weight[1] = Nob[1] / (Nob[1] + Nob[2]);
weight[1] = clamp((weight[1] - 0.5 * (1.0 - blend)) / blend, 0.0, 1.0);
weight[2] = 1.0 - weight[1];
}
else if (Nob[1] < (1.0 - limit) * (Nob[0] + Nob[2])) {
weight[0] = Nob[0] / (Nob[0] + Nob[2]);
weight[0] = clamp((weight[0] - 0.5 * (1.0 - blend)) / blend, 0.0, 1.0);
weight[2] = 1.0 - weight[0];
}
else {
/* last case, we have a mix between three */
weight[0] = ((2.0 - limit) * Nob[0] + (limit - 1.0)) / (2.0 * limit - 1.0);
weight[1] = ((2.0 - limit) * Nob[1] + (limit - 1.0)) / (2.0 * limit - 1.0);
weight[2] = ((2.0 - limit) * Nob[2] + (limit - 1.0)) / (2.0 * limit - 1.0);
}
}
else {
/* Desperate mode, no valid choice anyway, fallback to one side.*/
weight[0] = 1.0;
}
Color = color(0.0, 0.0, 0.0);
Alpha = 0.0;
float tmp_alpha;
if (weight[0] > 0.0) {
Color += weight[0] * image_texture_lookup(filename,
p[1],
p[2],
tmp_alpha,
compress_as_srgb,
ignore_alpha,
unassociate_alpha,
is_float,
interpolation,
extension);
Alpha += weight[0] * tmp_alpha;
}
if (weight[1] > 0.0) {
Color += weight[1] * image_texture_lookup(filename,
p[0],
p[2],
tmp_alpha,
compress_as_srgb,
ignore_alpha,
unassociate_alpha,
is_float,
interpolation,
extension);
Alpha += weight[1] * tmp_alpha;
}
if (weight[2] > 0.0) {
Color += weight[2] * image_texture_lookup(filename,
p[1],
p[0],
tmp_alpha,
compress_as_srgb,
ignore_alpha,
unassociate_alpha,
is_float,
interpolation,
extension);
Alpha += weight[2] * tmp_alpha;
}
}
else if (projection == "sphere") {
point projected = map_to_sphere(texco_remap_square(p));
Color = image_texture_lookup(filename,
projected[0],
projected[1],
Alpha,
compress_as_srgb,
ignore_alpha,
unassociate_alpha,
is_float,
interpolation,
extension);
}
else if (projection == "tube") {
point projected = map_to_tube(texco_remap_square(p));
Color = image_texture_lookup(filename,
projected[0],
projected[1],
Alpha,
compress_as_srgb,
ignore_alpha,
unassociate_alpha,
is_float,
interpolation,
extension);
}
}
|