source/blender/gpu/shaders/gpu_shader_image_overlays_merge_frag.glsl


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42


/* Merge overlays texture on top of image texture and transform to display space (assume sRGB) */

uniform sampler2D image_texture;
uniform sampler2D overlays_texture;
uniform bool display_transform;

in vec2 texCoord_interp;

out vec4 fragColor;

float linearrgb_to_srgb(float c)
{
  if (c < 0.0031308) {
    return (c < 0.0) ? 0.0 : c * 12.92;
  }
  else {
    return 1.055 * pow(c, 1.0 / 2.4) - 0.055;
  }
}

void linearrgb_to_srgb(vec4 col_from, out vec4 col_to)
{
  col_to.r = linearrgb_to_srgb(col_from.r);
  col_to.g = linearrgb_to_srgb(col_from.g);
  col_to.b = linearrgb_to_srgb(col_from.b);
  col_to.a = col_from.a;
}

void main()
{
  fragColor = texture(image_texture, texCoord_interp.st);

  vec4 overlay_col = texture(overlays_texture, texCoord_interp.st);

  fragColor *= 1.0 - overlay_col.a;
  fragColor += overlay_col;

  if (display_transform) {
    linearrgb_to_srgb(fragColor, fragColor);
  }
}