blob: 3f33de5e6b33cc08fbc754fc587bcd8f485cc216 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
|
print_text:
jsr wait_blank
; выключаем PPU
jsr disable_ppu
; выбираем последний CHR банк
lda #%00011111
jsr select_chr_solid_bank
; очищаем экран
jsr clear_screen
; загружаем палитру
lda #LOW(symbols_palette)
sta <PAL_SOURCE_ADDR
lda #HIGH(symbols_palette)
sta <PAL_SOURCE_ADDR+1
jsr preload_palette
jsr wait_blank_simple
jsr load_palette
lda #3
sta <TEXT_LINE
lda #1
sta <TEXT_POS
sta <SPRITES_ENABLED
lda #0
sta <TEXT_NAMETABLE
sta <TEXT_SCROLL_STARTED
jsr reset_scroll
jsr wait_blank_simple
jsr enable_ppu
.next_char:
ldy #0
lda [TEXT_SOURCE_ADDR], y
beq .end
cmp #$FF
bne .not_next_line
; переходим на следующую строку
jsr next_line
jmp .inc_source_pos
.not_next_line:
; печатаем символ
jsr symbol_print
lda <KONAMI_CODE_TRIGGERED
bne .exit_to_credits
.inc_source_pos:
inc <TEXT_SOURCE_ADDR
bne .inc_text_pos
inc <TEXT_SOURCE_ADDR+1
.inc_text_pos:
inc <TEXT_POS
jmp .next_char
.end:
lda <THE_END
beq .not_the_end
.endless_loop:
jsr wait_blank
lda <KONAMI_CODE_TRIGGERED
bne .exit_to_credits
jmp .endless_loop
.not_the_end
jsr wait_buttons_not_pressed
jsr wait_any_button
lda #0
sta <SPRITES_ENABLED
lda #LOW(symbols_palette)
sta <PAL_SOURCE_ADDR
lda #HIGH(symbols_palette)
sta <PAL_SOURCE_ADDR+1
jsr dim_out
rts
.exit_to_credits:
lda #0
sta <SPRITES_ENABLED
lda #LOW(symbols_palette)
sta <PAL_SOURCE_ADDR
lda #HIGH(symbols_palette)
sta <PAL_SOURCE_ADDR+1
jsr dim_out
jmp credits
; определяем адрес, куда писать символ
symbol_address:
pha
bit PPUSTATUS
lda <TEXT_NAMETABLE
bne .second_nametable
lda <TEXT_LINE
lsr A
lsr A
lsr A
clc
adc #$20
jmp .write_nametable_hi
.second_nametable:
lda <TEXT_LINE
lsr A
lsr A
lsr A
clc
adc #$28
.write_nametable_hi
sta PPUADDR
lda <TEXT_LINE
asl A
asl A
asl A
asl A
asl A
ora <TEXT_POS
sta PPUADDR
pla
rts
; печать символа из регистра A
symbol_print:
pha
; при удержании любой кнопки ускоряем
lda <BUTTONS
bne .skip_sprite_draw
; настраиваем спрайт
lda #$FF
sta SPRITES
pla
sta SPRITES+1
pha
lda #0
sta SPRITES+2
lda <TEXT_POS
asl A
asl A
asl A
sta SPRITES+3
jsr wait_blank
lda #0
sta OAMADDR
lda #HIGH(SPRITES)
sta OAMDMA
; плавно увеличиваем яркость
jsr preload_palette
jsr dim_4
jsr dim_4
jsr wait_blank
jsr .set_sprite_y
jsr load_sprite_palette
jsr preload_palette
jsr dim_4
jsr wait_blank
jsr .set_sprite_y
jsr load_sprite_palette
; скрываем спрайт
lda #$FF
sta SPRITES
jsr wait_blank
lda #0
sta OAMADDR
lda #HIGH(SPRITES)
sta OAMDMA
.skip_sprite_draw:
; вычисляем адреса
jsr symbol_address
pla
; печатаем символ
sta PPUDATA
inc <SYMBOL_COUNTER
; если зажата кнопка, то ждём vlank раз в 4 символа
lda <BUTTONS
beq .not_skip_vblank
lda <SYMBOL_COUNTER
and #%11
bne .skip_vblank
.not_skip_vblank:
jsr wait_blank
.skip_vblank:
rts
.set_sprite_y:
lda <TEXT_LINE
asl A
asl A
asl A
sec
sbc <SCROLL_POS
bcs .not_ovf
sec
sbc #16
.not_ovf
sec
sbc #1
ldx <SCROLL_POS
cpx <SCROLL_TARGET_POS
beq .not_scrolling
sec
sbc #1
.not_scrolling:
sta SPRITES
lda #0
sta OAMADDR
lda #HIGH(SPRITES)
sta OAMDMA
rts
; переход на следующую строку
next_line:
jsr wait_blank
lda #0
sta <TEXT_POS
; увеличиваем номер строки
inc <TEXT_LINE
lda <TEXT_LINE
; если он равен 30...
cmp #30
bne .scroll_check
; обнуляем строку
lda #0
sta <TEXT_LINE
; меняем nametable
lda TEXT_NAMETABLE
eor #1
sta <TEXT_NAMETABLE
; проверка, не пора ли начинать скроллинг
.scroll_check:
lda <TEXT_LINE
cmp #27 ; на какой строке начинать скроллить
bne .not_scroll_start
; пора
inc <TEXT_SCROLL_STARTED
.not_scroll_start:
; включен ли сейчас скроллиг?
lda <TEXT_SCROLL_STARTED
beq .clear_line
; увеличиваем скроллинг на 8 пикселей
lda <SCROLL_TARGET_POS
clc
adc #8
; если дошли до 240й строки, обнуляем
cmp #240
bne .not_next_nt
lda #0
.not_next_nt:
sta <SCROLL_TARGET_POS
; очищаем строку на противоположном nametable
.clear_line:
jsr wait_blank
bit PPUSTATUS
lda <TEXT_NAMETABLE
bne .second_nametable
lda <TEXT_LINE
lsr A
lsr A
lsr A
clc
adc #$28
jmp .write_nametable_hi
.second_nametable:
lda <TEXT_LINE
lsr A
lsr A
lsr A
clc
adc #$20
.write_nametable_hi
sta PPUADDR
lda <TEXT_LINE
asl A
asl A
asl A
asl A
asl A
sta PPUADDR
ldx #32
lda #0
.next_char:
sta PPUDATA
dex
bne .next_char
.end:
jsr wait_blank
rts
|