1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
|
project ('orc', 'c', version : '0.4.28',
meson_version : '>= 0.32.0',
default_options : ['buildtype=debugoptimized',
'warning_level=1',
'c_std=gnu99'] )
orc_api = '0.4'
orc_version_major = meson.project_version().split('.')[0]
orc_version_minor = meson.project_version().split('.')[1]
orc_version_micro = meson.project_version().split('.')[2]
# maintaining compatibility with the previous libtool versioning
soversion = 0
libversion = '@0@.@1@.0'.format(soversion, orc_version_micro.to_int())
add_global_arguments('-DHAVE_CONFIG_H', language : 'c')
orc_inc = include_directories('.')
cc = meson.get_compiler('c')
cdata = configuration_data() # config.h
pc_conf = configuration_data() # orc.pc
cdata.set('ORC_EXPORTS', true)
all_backends = ['sse', 'mmx', 'altivec', 'neon', 'mips', 'c64x'] # 'arm'
backend = get_option('enable-backend')
foreach b : all_backends
if backend == 'all' or backend == b
cdata.set('ENABLE_BACKEND_' + b.to_upper(), 1)
endif
endforeach
cpu_family = host_machine.cpu_family()
if cpu_family == 'x86'
cdata.set('HAVE_I386', true)
elif cpu_family == 'x86_64'
cdata.set('HAVE_AMD64', true)
elif cpu_family == 'powerpc'
cdata.set('HAVE_POWERPC', true)
elif cpu_family == 'arm'
cdata.set('HAVE_ARM', true)
elif cpu_family == 'mipsel'
cdata.set('HAVE_MIPSEL', true)
endif
libm = cc.find_library('m', required : false)
librt = []
pc_conf.set('LIBRT', '')
if cc.has_function('clock_gettime')
cdata.set('HAVE_CLOCK_GETTIME', true)
else
# On glibc older than 2.17, clock_gettime is provided by time.h and -lrt
librt = cc.find_library('rt', required : false)
if librt.found() and cc.has_function('clock_gettime', dependencies : librt)
pc_conf.set('LIBRT', '-lrt')
endif
endif
liblog = []
if cc.has_header_symbol('android/log.h', '__android_log_print')
cdata.set('HAVE_ANDROID_LIBLOG', true)
liblog = [cc.find_library('log', required : true)]
endif
host_os = host_machine.system()
if host_os == 'windows'
cdata.set('HAVE_CODEMEM_VIRTUALALLOC', true)
cdata.set('HAVE_OS_WIN32', true)
cdata.set('HAVE_THREAD_WIN32', true)
pc_conf.set('EXEEXT', '.exe')
pc_conf.set('PTHREAD_LIBS', '')
else
# If it is not windows, we just assume it is a unix of sorts for now.
cdata.set('HAVE_CODEMEM_MMAP', true)
cdata.set('HAVE_THREAD_PTHREAD', true)
pc_conf.set('EXEEXT', '')
if host_os == 'android'
pc_conf.set('PTHREAD_LIBS', '')
else
pc_conf.set('PTHREAD_LIBS', '-lpthread')
endif
endif
monotonic_test = '''
#include <time.h>
#include <unistd.h>
int main() {
#if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
#error No monotonic clock
#endif
return 0;
}
'''
cdata.set('HAVE_MONOTONIC_CLOCK', cc.compiles(monotonic_test))
cdata.set('HAVE_GETTIMEOFDAY', cc.has_function('gettimeofday'))
cdata.set('HAVE_POSIX_MEMALIGN', cc.has_function('posix_memalign'))
cdata.set('HAVE_MMAP', cc.has_function('mmap'))
cdata.set('HAVE_SYS_TIME_H', cc.has_header('sys/time.h'))
cdata.set('HAVE_UNISTD_H', cc.has_header('unistd.h'))
cdata.set('HAVE_VALGRIND_VALGRIND_H', cc.has_header('valgrind/valgrind.h'))
cdata.set_quoted('PACKAGE_VERSION', meson.project_version())
cdata.set_quoted('VERSION', meson.project_version())
subdir('orc')
subdir('orc-test')
subdir('tools')
subdir('examples')
subdir('testsuite')
if not meson.is_cross_build() and host_os != 'windows'
subdir('doc')
endif
pc_conf.set('prefix', get_option('prefix'))
pc_conf.set('exec_prefix', get_option('prefix'))
pc_conf.set('libdir', join_paths(get_option('prefix'), get_option('libdir')))
pc_conf.set('includedir', join_paths(get_option('prefix'), 'include'))
pc_conf.set('VERSION', meson.project_version())
pc_conf.set('ORC_MAJORMINOR', orc_api)
pc_conf.set('LIBM', libm.found() ? '-lm' : '')
pkgconfigdir = join_paths (get_option('libdir'), 'pkgconfig')
configure_file(input : 'orc.pc.in',
output : 'orc-' + orc_api + '.pc',
configuration : pc_conf,
install_dir : pkgconfigdir)
# Install m4 macro that other projects use
install_data('orc.m4', install_dir : 'share/aclocal')
configure_file(output : 'config.h', configuration : cdata)
|