blob: dcfde96ddae6c7664b0846fefe7845a698393f00 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
|
@ECHO OFF
REM (C) 2013-2016 see Authors.txt
REM
REM This file is part of MPC-HC.
REM
REM MPC-HC is free software; you can redistribute it and/or modify
REM it under the terms of the GNU General Public License as published by
REM the Free Software Foundation; either version 3 of the License, or
REM (at your option) any later version.
REM
REM MPC-HC is distributed in the hope that it will be useful,
REM but WITHOUT ANY WARRANTY; without even the implied warranty of
REM MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
REM GNU General Public License for more details.
REM
REM You should have received a copy of the GNU General Public License
REM along with this program. If not, see <http://www.gnu.org/licenses/>.
SETLOCAL
SET "FILE_DIR=%~dp0"
PUSHD "%FILE_DIR%"
SET ROOT_DIR=..\..\..
SET "COMMON=%FILE_DIR%%ROOT_DIR%\common.bat"
CALL "%COMMON%" :SubSetPath
IF %ERRORLEVEL% NEQ 0 EXIT /B 1
CALL "%COMMON%" :SubDoesExist gcc.exe
IF %ERRORLEVEL% NEQ 0 EXIT /B 1
SET ARG=/%*
SET ARG=%ARG:/=%
SET ARG=%ARG:-=%
SET ARGB=0
SET ARGBC=0
SET ARGCOMP=0
SET ARGPL=0
SET INPUT=0
SET VALID=0
IF /I "%ARG%" == "?" GOTO ShowHelp
FOR %%G IN (%ARG%) DO (
IF /I "%%G" == "help" GOTO ShowHelp
IF /I "%%G" == "Build" SET "BUILDTYPE=Build" & SET /A ARGB+=1
IF /I "%%G" == "Clean" SET "BUILDTYPE=Clean" & SET /A ARGB+=1
IF /I "%%G" == "Rebuild" SET "BUILDTYPE=Rebuild" & SET /A ARGB+=1
IF /I "%%G" == "Both" SET "ARCH=Both" & SET /A ARGPL+=1
IF /I "%%G" == "Win32" SET "ARCH=x86" & SET /A ARGPL+=1
IF /I "%%G" == "x86" SET "ARCH=x86" & SET /A ARGPL+=1
IF /I "%%G" == "x64" SET "ARCH=x64" & SET /A ARGPL+=1
IF /I "%%G" == "Debug" SET "RELEASETYPE=Debug" & SET /A ARGBC+=1
IF /I "%%G" == "Release" SET "RELEASETYPE=Release" & SET /A ARGBC+=1
IF /I "%%G" == "VS2015" SET "COMPILER=VS2015" & SET /A ARGCOMP+=1
IF /I "%%G" == "Silent" SET "SILENT=True" & SET /A VALID+=1
IF /I "%%G" == "Nocolors" SET "NOCOLORS=True" & SET /A VALID+=1
)
FOR %%X IN (%*) DO SET /A INPUT+=1
SET /A VALID+=%ARGB%+%ARGPL%+%ARGBC%+%ARGCOMP%
IF %VALID% NEQ %INPUT% GOTO UnsupportedSwitch
IF %ARGB% GTR 1 (GOTO UnsupportedSwitch) ELSE IF %ARGB% == 0 (SET "BUILDTYPE=Build")
IF %ARGPL% GTR 1 (GOTO UnsupportedSwitch) ELSE IF %ARGPL% == 0 (SET "ARCH=Both")
IF %ARGBC% GTR 1 (GOTO UnsupportedSwitch) ELSE IF %ARGBC% == 0 (SET "RELEASETYPE=Release")
IF %ARGCOMP% GTR 1 (GOTO UnsupportedSwitch) ELSE IF %ARGCOMP% == 0 (SET "COMPILER=VS2015")
IF NOT DEFINED VS140COMNTOOLS GOTO MissingVar
SET "TOOLSET=%VS140COMNTOOLS%..\..\VC\vcvarsall.bat"
SET "BIN_DIR=%ROOT_DIR%\bin"
IF /I "%ARCH%" == "Both" (
SET "ARCH=x86" & CALL :Main
SET "ARCH=x64" & CALL :Main
) ELSE (
CALL :Main
)
GOTO End
:Main
IF %ERRORLEVEL% NEQ 0 EXIT /B
REM Always use x86_amd64 compiler, even on 64bit windows, because this is what VS is doing
IF /I "%ARCH%" == "x86" (SET TOOLSETARCH=x86) ELSE (SET TOOLSETARCH=x86_amd64)
CALL "%TOOLSET%" %TOOLSETARCH%
SET START_TIME=%TIME%
SET START_DATE=%DATE%
IF /I "%BUILDTYPE%" == "Rebuild" (
SET "BUILDTYPE=Clean" & CALL :SubMake
SET "BUILDTYPE=Build" & CALL :SubMake
SET "BUILDTYPE=Rebuild"
EXIT /B
)
IF /I "%BUILDTYPE%" == "Clean" (CALL :SubMake & EXIT /B)
CALL :SubMake
EXIT /B
:End
IF %ERRORLEVEL% NEQ 0 EXIT /B %ERRORLEVEL%
TITLE Compiling LAV Filters %COMPILER% [FINISHED]
SET END_TIME=%TIME%
CALL "%COMMON%" :SubGetDuration
CALL "%COMMON%" :SubMsg "INFO" "LAV Filters compilation started on %START_DATE%-%START_TIME% and completed on %DATE%-%END_TIME% [%DURATION%]"
POPD
ENDLOCAL
EXIT /B
:SubMake
IF %ERRORLEVEL% NEQ 0 EXIT /B
IF /I "%ARCH%" == "x86" (SET "ARCHVS=Win32") ELSE (SET "ARCHVS=x64")
REM Build FFmpeg
sh build_ffmpeg.sh %ARCH% %RELEASETYPE% %BUILDTYPE% %COMPILER%
IF %ERRORLEVEL% NEQ 0 (
CALL "%COMMON%" :SubMsg "ERROR" "'sh build_ffmpeg.sh %ARCH% %RELEASETYPE% %BUILDTYPE% %COMPILER%' failed!"
EXIT /B
)
PUSHD src
REM Build LAVFilters
IF /I "%ARCH%" == "x86" (SET "ARCHVS=Win32") ELSE (SET "ARCHVS=x64")
MSBuild.exe LAVFilters.sln /nologo /consoleloggerparameters:Verbosity=minimal /nodeReuse:true /m /t:%BUILDTYPE% /property:Configuration=%RELEASETYPE%;Platform=%ARCHVS%
IF %ERRORLEVEL% NEQ 0 (
CALL "%COMMON%" :SubMsg "ERROR" "'MSBuild.exe LAVFilters.sln /nologo /consoleloggerparameters:Verbosity=minimal /nodeReuse:true /m /t:%BUILDTYPE% /property:Configuration=%RELEASETYPE%;Platform=%ARCHVS%' failed!"
EXIT /B
)
POPD
IF /I "%RELEASETYPE%" == "Debug" (
SET "SRCFOLDER=src\bin_%ARCHVS%d"
) ELSE (
SET "SRCFOLDER=src\bin_%ARCHVS%"
)
IF /I "%RELEASETYPE%" == "Debug" (
SET "DESTFOLDER=%BIN_DIR%\mpc-hc_%ARCH%_Debug"
) ELSE (
SET "DESTFOLDER=%BIN_DIR%\mpc-hc_%ARCH%"
)
IF /I "%ARCH%" == "x64" (
SET "DESTFOLDER=%DESTFOLDER%\LAVFilters64"
) ELSE (
SET "DESTFOLDER=%DESTFOLDER%\LAVFilters"
)
IF /I "%BUILDTYPE%" == "Build" (
REM Copy LAVFilters files to MPC-HC output directory
IF NOT EXIST %DESTFOLDER% MD %DESTFOLDER%
COPY /Y /V %SRCFOLDER%\*.dll %DESTFOLDER%
COPY /Y /V %SRCFOLDER%\*.ax %DESTFOLDER%
COPY /Y /V %SRCFOLDER%\*.manifest %DESTFOLDER%
IF /I "%RELEASETYPE%" == "Release" (
COPY /Y /V %SRCFOLDER%\IntelQuickSyncDecoder\IntelQuickSyncDecoder.pdb %DESTFOLDER%
COPY /Y /V %SRCFOLDER%\LAVAudio\LAVAudio.pdb %DESTFOLDER%
COPY /Y /V %SRCFOLDER%\LAVSplitter\LAVSplitter.pdb %DESTFOLDER%
COPY /Y /V %SRCFOLDER%\LAVVideo\LAVVideo.pdb %DESTFOLDER%
COPY /Y /V %SRCFOLDER%\libbluray\libbluray.pdb %DESTFOLDER%
) ELSE (
COPY /Y /V %SRCFOLDER%\*.pdb %DESTFOLDER%
)
) ELSE IF /I "%BUILDTYPE%" == "Clean" (
REM Remove LAVFilters files in MPC-HC output directory
IF EXIST %DESTFOLDER% RD /Q /S %DESTFOLDER%
)
EXIT /B
:MissingVar
ECHO Not all build dependencies were found.
ECHO.
ECHO See "%ROOT_DIR%\docs\Compilation.txt" for more information.
CALL "%COMMON%" :SubMsg "ERROR" "LAV Filters compilation failed!" & EXIT /B 1
:UnsupportedSwitch
ECHO.
ECHO Unsupported commandline switch!
ECHO.
ECHO "%~nx0 %*"
ECHO.
ECHO Run "%~nx0 help" for details about the commandline switches.
CALL "%COMMON%" :SubMsg "ERROR" "LAV Filters compilation failed!" & EXIT /B 1
:ShowHelp
TITLE %~nx0 Help
ECHO.
ECHO Usage:
ECHO %~nx0 [Clean^|Build^|Rebuild] [x86^|x64^|Both] [Debug^|Release] [VS2015]
ECHO.
ECHO Notes: You can also prefix the commands with "-", "--" or "/".
ECHO The arguments are not case sensitive and can be ommitted.
ECHO. & ECHO.
ECHO Executing %~nx0 without any arguments will use the default ones:
ECHO "%~nx0 Build Both Release VS2015"
ECHO.
POPD
ENDLOCAL
EXIT /B
|
