qmake/protobuf.pri: new file to include in .pro files for depending on protobuf.

This introduces a protobuf.pri helper that .pro files can include to
depend on protobuf.

Including protobuf.pri will link against the protobuf library, and include
the proper headers.

1 files changed, 39 insertions, 0 deletions

diff --git a/qmake/protobuf.pri b/qmake/protobuf.pri
new file mode 100644
index 000000000..7022fe649
--- /dev/null
+++ b/qmake/protobuf.pri
@@ -0,0 +1,39 @@
+# Copyright 2005-2017 The Mumble Developers. All rights reserved.
+# Use of this source code is governed by a BSD-style license
+# that can be found in the LICENSE file at the root of the
+# Mumble source tree or at <https://www.mumble.info/LICENSE>.
+
+include(pkgconfig.pri)
+
+# Include this file to portably link
+# against protobuf.
+#
+# It requires compiler.pri to be included
+# for $$PROTOBUF_PATH, etc. to work on win32.
+# This file can't include compiler.pri: it can
+# only be included once per .pro file.
+
+win32-msvc* {
+	# Legacy win32-static paths (protobuf 2.x)
+	INCLUDEPATH *= "$$PROTOBUF_PATH/vsprojects/include" "$$PROTOBUF_PATH/src" protobuf
+	CONFIG(debug, debug|release) {
+		QMAKE_LIBDIR *= "$$PROTOBUF_PATH/vsprojects/Debug"
+	} else {
+		QMAKE_LIBDIR *= "$$PROTOBUF_PATH/vsprojects/Release"
+	}
+
+	# New win32-static paths (protobuf 3.2+)
+	INCLUDEPATH *= "$$PROTOBUF_PATH/include"
+	QMAKE_LIBDIR *= "$$PROTOBUF_PATH/lib"
+
+	LIBS *= -llibprotobuf
+}
+
+win32-g++ {
+	LIBS *= -lprotobuf
+}
+
+unix {
+	CONFIG *= link_pkgconfig
+	must_pkgconfig(protobuf)
+}