blob: 6a9b0b52239a49219c3ebc3dec8c55056b4e41a1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Copyright 2005-2016 The Mumble Developers. All rights reserved.
# Use of this source code is governed by a BSD-style license
# that can be found in the LICENSE file at the root of the
# Mumble source tree or at <https://www.mumble.info/LICENSE>.
include(../../compiler.pri)
PROTOBUF *= ../Mumble.proto
pbh.output = ${QMAKE_FILE_BASE}.pb.h
pbh.depends = ${QMAKE_FILE_BASE}.pb.cc
pbh.commands = $$escape_expand(\\n)
pbh.input = PROTOBUF
pbh.CONFIG *= no_link explicit_dependencies target_predeps
pbh.variable_out = HEADERS
pb.output = ${QMAKE_FILE_BASE}.pb.cc
pb.commands = protoc --cpp_out=. -I. -I.. ${QMAKE_FILE_NAME}
pb.input = PROTOBUF
pb.CONFIG *= no_link explicit_dependencies
pb.variable_out = SOURCES
TEMPLATE = lib
CONFIG -= qt
CONFIG += debug_and_release
CONFIG += staticlib
INCLUDEPATH *= "$$PROTOBUF_PATH/vsprojects/include" "$$PROTOBUF_PATH/src" protobuf
QMAKE_EXTRA_COMPILERS *= pb pbh
!CONFIG(third-party-warnings) {
# We ignore warnings in third party builds. We won't actually look
# at them and they clutter out our warnings.
CONFIG -= warn_on
CONFIG += warn_off
}
CONFIG(debug, debug|release) {
DESTDIR = ../../debug
}
CONFIG(release, debug|release) {
DESTDIR = ../../release
}
include(../../symbols.pri)
|
