blob: 729e5a220b11198d15f74b9079ccb30a8e19360b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 2005-2017 The Mumble Developers. All rights reserved.
# Use of this source code is governed by a BSD-style license
# that can be found in the LICENSE file at the root of the
# Mumble source tree or at <https://www.mumble.info/LICENSE>.
include(../../../compiler.pri)
SLICEFILES = ../Murmur.ice
slice.output = ${QMAKE_FILE_BASE}.cpp
win32 {
slice.commands = slice2cpp --checksum -I\"$$ICE_PATH/slice\" ${QMAKE_FILE_NAME}
} else {
ICE_VERSION = $$system(slice2cpp --version 2>&1)
EXTRA_SLICEFLAGS =
!isEmpty(ICE_VERSION) {
EXTRA_SLICEFLAGS = -I/usr/share/Ice-$$ICE_VERSION/slice/
}
slice.commands = slice2cpp --checksum -I/usr/local/share/Ice -I/usr/share/Ice/slice -I/usr/share/slice $$EXTRA_SLICEFLAGS ${QMAKE_FILE_NAME}
}
slice.input = SLICEFILES
slice.CONFIG *= no_link explicit_dependencies
slice.variable_out = SOURCES
sliceh.output = ${QMAKE_FILE_BASE}.h
sliceh.depends = ${QMAKE_FILE_BASE}.cpp
sliceh.commands = $$escape_expand(\\n)
sliceh.input = SLICEFILES
sliceh.CONFIG *= no_link explicit_dependencies target_predeps
TEMPLATE = lib
CONFIG -= qt
CONFIG += debug_and_release
CONFIG += staticlib
QMAKE_EXTRA_COMPILERS *= slice sliceh
win32 {
INCLUDEPATH *= "$$ICE_PATH/include"
CONFIG(static) {
DEFINES *= ICE_STATIC_LIBS
}
}
macx {
INCLUDEPATH *= $$(MUMBLE_PREFIX)/Ice-3.4.2/include/
slice.commands = $$(MUMBLE_PREFIX)/Ice-3.4.2/bin/slice2cpp --checksum -I$$(MUMBLE_PREFIX)/Ice-3.4.2/slice/ ../Murmur.ice
}
CONFIG(ermine) {
INCLUDEPATH *= $$(MUMBLE_ICE_PREFIX)/include/
slice.commands = $$(MUMBLE_ICE_PREFIX)/bin/slice2cpp --checksum -I$$(MUMBLE_ICE_PREFIX)/slice/ ../Murmur.ice
}
unix:!macx:CONFIG(static) {
INCLUDEPATH *= /opt/Ice-3.3/include
slice.commands = /opt/Ice-3.3/bin/slice2cpp --checksum -I/opt/Ice-3.3/slice ../Murmur.ice
}
macx:CONFIG(static) {
LIBS *= -lbz2 -liconv
QMAKE_CXXFLAGS *= -fPIC
}
!CONFIG(third-party-warnings) {
# We ignore warnings in third party builds. We won't actually look
# at them and they clutter out our warnings.
CONFIG -= warn_on
CONFIG += warn_off
}
CONFIG(debug, debug|release) {
DESTDIR = ../../../debug
}
CONFIG(release, debug|release) {
DESTDIR = ../../../release
}
include(../../../symbols.pri)
|
