T54991: Restore support for Motion Path drawing in 2.8

This commit restores support for Motion Path drawing in 2.8 (as it wasn't ported over
to the new draw engines earlier, and the existing space_view3d/drawanimviz.c code was
removed during the Blender Internal removal).

Notes:
* Motion Paths are now implemented as an overlay (enabled by default).
  Therefore, you can turn all of them on/off from the "Overlays" popover

* By and large, we have kept the same draw style as was used in 2.7
  Further changes can happen later following further design work.

* One change from 2.7 is that thicker lines are used by default (2px vs 1px)


Todo's:
* There are some bad-level calls introduced here (i.e. the actgroup_to_keylist() stuff).
  These were introduced to optimise drawing performance (by avoiding full keyframes -> keylist
  conversion step on each drawcall). Instead, this has been moved to the calculation step
  (in blenkernel).  Soon, there will be some cleanups/improvements with those functions,
  so until then, we'll keep the bad level calls.


Credits:
* Clément Foucault (fclem) - Draw Engine magic + Shader Conversion/Optimisation
* Joshua Leung (Aligorith) - COW fixes, UI integration, etc.


Revision History:
See "tmp-b28-motionpath_drawing" branch (rBa12ab5b2ef49ccacae091ccb54d72de0d63f990d)

4 files changed, 180 insertions, 0 deletions

diff --git a/source/blender/draw/modes/shaders/animviz_mpath_lines_geom.glsl b/source/blender/draw/modes/shaders/animviz_mpath_lines_geom.glsl
new file mode 100644
index 00000000000..d9d59880e99
--- /dev/null
+++ b/source/blender/draw/modes/shaders/animviz_mpath_lines_geom.glsl
@@ -0,0 +1,38 @@
+
+layout(lines) in;
+layout(triangle_strip, max_vertices = 4) out;
+
+uniform mat4 ProjectionMatrix;
+uniform vec2 viewportSize;
+uniform int lineThickness = 2;
+
+in vec4 finalColor_geom[];
+in vec2 ssPos[];
+
+out vec4 finalColor;
+
+vec2 compute_dir(vec2 v0, vec2 v1)
+{
+	vec2 dir = normalize(v1 - v0 + 1e-8);
+	dir = vec2(-dir.y, dir.x);
+	return dir;
+}
+
+void main(void)
+{
+	vec2 t;
+	vec2 edge_dir = compute_dir(ssPos[0], ssPos[1]) / viewportSize;
+
+	bool is_persp = (ProjectionMatrix[3][3] == 0.0);
+
+	finalColor = finalColor_geom[0];
+	t = edge_dir * (float(lineThickness) * (is_persp ? gl_in[0].gl_Position.w : 1.0));
+	gl_Position = gl_in[0].gl_Position + vec4(t, 0.0, 0.0); EmitVertex();
+	gl_Position = gl_in[0].gl_Position - vec4(t, 0.0, 0.0); EmitVertex();
+
+	finalColor = finalColor_geom[1];
+	t = edge_dir * (float(lineThickness) * (is_persp ? gl_in[1].gl_Position.w : 1.0));
+	gl_Position = gl_in[1].gl_Position + vec4(t, 0.0, 0.0); EmitVertex();
+	gl_Position = gl_in[1].gl_Position - vec4(t, 0.0, 0.0); EmitVertex();
+	EndPrimitive();
+}
diff --git a/source/blender/draw/modes/shaders/animviz_mpath_lines_vert.glsl b/source/blender/draw/modes/shaders/animviz_mpath_lines_vert.glsl
new file mode 100644
index 00000000000..276f4004fb6
--- /dev/null
+++ b/source/blender/draw/modes/shaders/animviz_mpath_lines_vert.glsl
@@ -0,0 +1,91 @@
+
+uniform mat4 ViewMatrix;
+uniform mat4 ViewProjectionMatrix;
+uniform vec2 viewportSize;
+
+uniform int frameCurrent;
+uniform int frameStart;
+uniform int frameEnd;
+uniform int cacheStart;
+uniform bool selected;
+uniform bool useCustomColor;
+uniform vec3 customColor;
+
+in vec3 pos;
+
+out vec2 ssPos;
+out vec4 finalColor_geom;
+
+/* project to screen space */
+vec2 proj(vec4 pos)
+{
+	return (0.5 * (pos.xy / pos.w) + 0.5) * viewportSize;
+}
+
+#define SET_INTENSITY(A, B, C, min, max) (((1.0 - (float(C - B) / float(C - A))) * (max - min)) + min)
+
+void main()
+{
+	gl_Position = ViewProjectionMatrix * vec4(pos, 1.0);
+
+	ssPos = proj(gl_Position);
+
+	int frame = gl_VertexID + cacheStart;
+
+	float intensity;  /* how faint */
+
+	vec3 blend_base = (abs(frame - frameCurrent) == 1) ? colorCurrentFrame.rgb : colorBackground.rgb; /* "bleed" cframe color to ease color blending */
+
+	/* TODO: We might want something more consistent with custom color and standard colors. */
+	if (frame < frameCurrent) {
+		if (useCustomColor) {
+			/* Custom color: previous frames color is darker than current frame */
+			finalColor_geom.rgb = customColor * 0.25;
+		}
+		else {
+			/* black - before frameCurrent */
+			if (selected) {
+				intensity = SET_INTENSITY(frameStart, frame, frameCurrent, 0.25, 0.75);
+			}
+			else {
+				intensity = SET_INTENSITY(frameStart, frame, frameCurrent, 0.68, 0.92);
+			}
+			finalColor_geom.rgb = mix(colorWire.rgb, blend_base, intensity);
+		}
+	}
+	else if (frame > frameCurrent) {
+		if (useCustomColor) {
+			/* Custom color: next frames color is equal to user selected color */
+			finalColor_geom.rgb = customColor;
+		}
+		else {
+			/* blue - after frameCurrent */
+			if (selected) {
+				intensity = SET_INTENSITY(frameCurrent, frame, frameEnd, 0.25, 0.75);
+			}
+			else {
+				intensity = SET_INTENSITY(frameCurrent, frame, frameEnd, 0.68, 0.92);
+			}
+
+			finalColor_geom.rgb = mix(colorBonePose.rgb, blend_base, intensity);
+		}
+	}
+	else {
+		if (useCustomColor) {
+			/* Custom color: current frame color is slightly darker than user selected color */
+			finalColor_geom.rgb = customColor * 0.5;
+		}
+		else {
+			/* green - on frameCurrent */
+			if (selected) {
+				intensity = 0.5f;
+			}
+			else {
+				intensity = 0.99f;
+			}
+			finalColor_geom.rgb = clamp(mix(colorCurrentFrame.rgb, colorBackground.rgb, intensity) - 0.1, 0.0, 0.1);
+		}
+	}
+
+	finalColor_geom.a = 1.0;
+}
diff --git a/source/blender/draw/modes/shaders/animviz_mpath_points_vert.glsl b/source/blender/draw/modes/shaders/animviz_mpath_points_vert.glsl
new file mode 100644
index 00000000000..3b2f170ca22
--- /dev/null
+++ b/source/blender/draw/modes/shaders/animviz_mpath_points_vert.glsl
@@ -0,0 +1,47 @@
+
+uniform mat4 ViewProjectionMatrix;
+
+uniform int pointSize = 2;
+uniform int frameCurrent;
+uniform int cacheStart;
+uniform bool showKeyFrames = true;
+uniform bool useCustomColor;
+uniform vec3 customColor;
+
+in vec3 pos;
+in int flag;
+
+#define MOTIONPATH_VERT_SEL (1 << 0)
+#define MOTIONPATH_VERT_KEY (1 << 1)
+
+out vec4 finalColor;
+
+void main()
+{
+	gl_Position = ViewProjectionMatrix * vec4(pos, 1.0);
+	gl_PointSize = float(pointSize + 2);
+
+	int frame = gl_VertexID + cacheStart;
+	finalColor = (useCustomColor) ? vec4(customColor, 1.0) : vec4(1.0);
+
+	/* Bias to reduce z fighting with the path */
+	gl_Position.z -= 1e-4;
+
+	if (showKeyFrames) {
+		if ((flag & MOTIONPATH_VERT_KEY) != 0) {
+			gl_PointSize = float(pointSize + 5);
+			finalColor = colorVertexSelect;
+			/* Bias more to get these on top of regular points */
+			gl_Position.z -= 1e-4;
+		}
+		/* Draw big green dot where the current frame is.
+		 * NOTE: this is only done when keyframes are shown, since this adds similar types of clutter
+		 */
+		if (frame == frameCurrent) {
+			gl_PointSize = float(pointSize + 8);
+			finalColor = colorCurrentFrame;
+			/* Bias more to get these on top of keyframes */
+			gl_Position.z -= 1e-4;
+		}
+	}
+}
diff --git a/source/blender/draw/modes/shaders/common_globals_lib.glsl b/source/blender/draw/modes/shaders/common_globals_lib.glsl
index 4a0104e2cf2..c55457bb6d2 100644
--- a/source/blender/draw/modes/shaders/common_globals_lib.glsl
+++ b/source/blender/draw/modes/shaders/common_globals_lib.glsl
@@ -48,6 +48,10 @@ layout(std140) uniform globalsBlock {
 	vec4 colorNurbSelUline;
 	vec4 colorActiveSpline;
 
+	vec4 colorBonePose;
+
+	vec4 colorCurrentFrame;
+
 	vec4 colorGrid;
 	vec4 colorGridEmphasise;
 	vec4 colorGridAxisX;